Threaded Mode | Linear Mode

SlideRule · 06-16-2020, 04:08 PM

An excerpt from Programmable Calculator Evaluation of Real Determinants, Interface Age, May 1980 (pgs 104-107), M. Patt & L. Fisher {University of Lowell}

" … pocket calculator program … presented for use with the Texas Instruments Model SR-52 (Algebraic) … self-contained and complete, fits on a single magnetic card … enable an operator to quickly evaluate real determinants of sizes two-by-two through six-by-six … most accurate when all determinant elements are integers. Errors are generally less than 0.001 % for a six-by-six (worst case) determinant with all integer elements.
SOLUTION BY GAUSSIAN ELIMINATION
The program written for the SR-52 calculator evaluates the determinant by a modified Gaussian elimination process. Through the systematic addition of rows, this procedure develops a lower-triangular matrix whose determinant is equal to that of the original matrix. The determinant is then evaluated by taking the trace (product of elements on the diagonal) of the lower-triangular matrix … "

BEST!
SlideRule

TIguy · 05-02-2024, 09:15 AM

As author (Fisher) of the article mentioned, thanks.

I'm sure many programmers of calculators of that time can identify with, the challenge in programming was limited data register count (nominally 20) and limited program storage (223 steps). I ended up packing one data register with both an index table (most significant digits) and code (least significant digits).

Ah, simple times, LOL.

Thomas Klemm · (This post was last modified: Yesterday 12:34 PM by Thomas Klemm.)

The article contains also a program for the HP-67.
It can be used with this online-emulator: HP-67
Click the emulator display for the menu page, → Program and just paste the following code:

Code:

PROG

224

 31 25 11 : f LBL A

 35 71 00 : h F? 0

 22 11    : GTO A

 35 51 00 : h SF 0

 31 51    : f x=0

 34 06    : RCL 6

 33 05    : STO 5

 84       : R/S

 31 25 11 : f LBL A

 34 05    : RCL 5

 81       : /

 33 24    : STO (i)

 31 33    : f DSZ

 35 34    : h RC I

 33 09    : STO 9

 01       : 1

 33 08    : STO 8

 51       : -

 84       : R/S

 31 25 12 : f LBL B

 31 22 07 : f GSB 7

 01       : 1

 00       : 0

 22 09    : GTO 9

 31 25 13 : f LBL C

 31 22 08 : f GSB 8

 01       : 1

 04       : 4

 22 09    : GTO 9

 31 25 14 : f LBL D

 35 71 01 : h F? 1

 22 14    : GTO D

 33 14    : STO D

 01       : 1

 04       : 4

 31 22 03 : f GSB 3

 34 14    : RCL D

 31 25 14 : f LBL D

 31 22 07 : f GSB 7

 01       : 1

 07       : 7

 22 09    : GTO 9

 31 25 15 : f LBL E

 35 71 00 : h F? 0

 22 15    : GTO E

 33 14    : STO D

 01       : 1

 07       : 7

 31 22 03 : f GSB 3

 01       : 1

 07       : 7

 31 22 04 : f GSB 4

 34 14    : RCL D

 31 25 15 : f LBL E

 31 22 08 : f GSB 8

 01       : 1

 09       : 9

 22 09    : GTO 9

 32 25 15 : g LBL f E

 35 71 01 : h F? 1

 22 31 15 : GTO f E

 33 14    : STO D

 01       : 1

 09       : 9

 31 22 03 : f GSB 3

 01       : 1

 09       : 9

 31 22 04 : f GSB 4

 01       : 1

 09       : 9

 31 22 05 : f GSB 5

 34 14    : RCL D

 32 25 15 : g LBL f E

 31 22 07 : f GSB 7

 00       : 0

 31 25 09 : f LBL 9

 00       : 0

 35 51 02 : h SF 2

 35 22    : h RTN

 31 25 07 : f LBL 7

 35 71 01 : h F? 1

 31 22 09 : f GSB 9

 35 71 01 : h F? 1

 84       : R/S

 35 61 00 : h CF 00

 35 51 01 : h SF 1

 22 07    : GTO 7

 31 25 08 : f LBL 8

 35 71 00 : h F? 0

 31 22 09 : f GSB 9

 35 71 00 : h F? 0

 84       : R/S

 35 61 01 : h CF 01

 35 51 00 : h SF 0

 31 25 07 : f LBL 7

 33 14    : STO D

 34 06    : RCL 6

 09       : 9

 81       : /

 33 07    : STO 7

 34 14    : RCL D

 31 51    : f x=0

 35 53    : h Rv

 31 51    : f x=0

 34 07    : RCL 7

 33 14    : STO D

 33 71 05 : STO * 5

 35 22    : h RTN

 31 25 05 : f LBL 5

 31 22 07 : f GSB 7

 01       : 1

 07       : 7

 22 05    : GTO 5

 31 25 04 : f LBL 4

 31 22 07 : f GSB 7

 01       : 1

 04       : 4

 22 04    : GTO 4

 31 25 03 : f LBL 3

 31 22 07 : f GSB 7

 01       : 1

 00       : 0

 31 22 06 : f GSB 6

 31 25 04 : f LBL 4

 31 22 06 : f GSB 6

 31 25 05 : f LBL 5

 31 22 06 : f GSB 6

 31 25 06 : f LBL 6

 34 24    : RCL (i)

 22 02    : GTO 2

 31 25 07 : f LBL 7

 35 33    : h ST I

 35 51 02 : h SF 2

 09       : 9

 33 81 07 : STO / 7

 35 53    : h Rv

 35 22    : h RTN

 31 25 09 : f LBL 9

 34 14    : RCL D

 81       : /

 31 25 02 : f LBL 2

 35 52    : h x<->y

 35 24    : h x<->I

 35 53    : h Rv

 34 24    : RCL (i)

 51       : -

 31 34    : f ISZ

 35 53    : h Rv

 35 24    : h x<->I

 35 54    : h R^

 35 71 02 : h F? 2

 22 02    : GTO 2

 34 15    : RCL E

 81       : /

 33 24    : STO (i)

 31 34    : f ISZ

 32 25 14 : g LBL f D

 35 53    : h Rv

 35 53    : h Rv

 35 24    : h x<->I

 35 33    : h ST I

 31 34    : f ISZ

 35 54    : h R^

 35 22    : h RTN

 31 25 02 : f LBL 2

 31 61    : f x!=0

 22 02    : GTO 2

 35 53    : h Rv

 34 07    : RCL 7

 31 25 02 : f LBL 2

 33 71 08 : STO * 8

 33 15    : STO E

 22 31 14 : GTO f D

 32 25 13 : g LBL f C

 34 09    : RCL 9

 02       : 2

 71       : *

 35 33    : h ST I

 22 07    : GTO 7

 00       : 0

 22 09    : GTO 9

 32 22 15 : g GSB f E

 22 31 13 : GTO f C

 31 22 15 : f GSB E

 22 31 13 : GTO f C

 31 22 14 : f GSB D

 22 31 13 : GTO f C

 22 08    : GTO 8

 31 25 07 : f LBL 7

 22 24    : GTO (i)

 31 25 09 : f LBL 9

 31 22 03 : f GSB 3

 00       : 0

 31 22 04 : f GSB 4

 00       : 0

 31 22 05 : f GSB 5

 34 00    : RCL 0

 31 42    : f P<>S

 34 09    : RCL 9

 51       : -

 31 42    : f P<>S

 33 71 05 : STO * 5

 22 08    : GTO 8

 32 25 13 : g LBL f C

 34 14    : RCL D

 33 81 05 : STO / 5

 31 25 08 : f LBL 8

 34 08    : RCL 8

 33 71 05 : STO * 5

 34 05    : RCL 5

 23 00    : DSP 0

 31 24    : RND

 35 84    : h SPACE

 84       : R/S

 32 25 11 : g LBL f A

 31 43    : f CL REG

 35 61 00 : h CF 00

 35 61 01 : h CF 01

 43       : EEX

 04       : 4

 42       : CHS

 33 06    : STO 6

 44       : CLx

 35 22    : h RTN

DATA

26

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

 0

STATE

7

DEG

FIX

2

1

0

1

1

HELP

1

CARD

11

Title: Real Determinants

A: 1st

B: 2nd

C: 3rd

D: 4th

E: 5th

a: reset

b: 

c: answer

d: 

e: 6th

END

There's a typo in the listing at line 4:

Code:

STF 0    31 51 00

That should be:

Code:

SF 0     35 51 00

Example

\(
\begin{vmatrix}
2 & 11 & 23 & 41 \\
3 & 13 & 29 & 43 \\
5 & 17 & 31 & 47 \\
7 & 19 & 37 & 53 \\
\end{vmatrix}
= 880
\)

f a
0.00

2 A
3 A
5 A
7 A
-4.00

11 B
13 B
17 B
19 B
3.00

23 C
29 C
31 C
37 C
3.00

41 D
43 D
47 D
53 D
3.00

f c
880.

PS: It's nice to have the author here in this forum.

**Gene** · Yesterday, 12:35 PM

Interesting! Downloaded the article to see how you did this given the SR-52 memory “constraints”

You used the two extra registers R98 and R99. You also used a register of program memory R88 as a data register and then used 7 of the SR-52’s pending operation registers for data (R63 - R69)

Bravo. Have any other SR-52 material lying about ?

Thomas Klemm · Yesterday, 12:42 PM

On closer inspection I noticed other typos.

Line 74:

Code:

GSB 7a    22 07

Should we rather trust the code or the key sequence?

Code:

074: 22 07    : GTO 7

A GTO instruction would make the next line dead code.
Thus I'd got with the key sequence:

Code:

074: 31 22 07 : f GSB 7

This also fixed the Error I got when using subroutine e for the 2nd time.

Line 135:

Code:

STO / 9    33 81 07

Code:

135: 33 81 07 : STO / 7

The description of register 7 is: Modified zero approximator
Based on the following table I assume that the typo is in the key sequence.

Replacement
1.0 × 10^-4
1.1 × 10^-5
1.2 × 10^-6
1.4 × 10^-7
1.5 × 10^-8

This is the sequence we get if 10^-4 gets divided by 9.
Therefore I keep the line as is.

Meanwhile I've updated the program accordingly in my previous post.