+- HP Forums (https://www.hpmuseum.org/forum)
+-- Forum: HP Software Libraries (/forum-10.html)
+--- Forum: General Software Library (/forum-13.html)
+--- Thread: (42S) Interest Rate Conversion (/thread-14028.html)
(42S) Interest Rate Conversion - Dave Britten - 11-21-2019 03:24 PM
This program acts like the interest rate conversion menu in the 17BII, but simplified into a single menu that does both periodic and continuous compounding.
The program displays five menu items:
NOM% - Enter or compute nominal interest rate.
EFF% - Enter or compute effective interest rate.
P/YR - Enter or view number of compounding periods per year, and switch to periodic compounding.
PER - Switch to periodic compounding.
CON - Switch to continuous compounding (P/YR is ignored in this mode).
To use:
Enter a nominal or effective interest rate and press the appropriate NOM% or EFF% key to store the value. Enter the number of compounding periods per year, and press P/YR, or press CON for continuous compounding. (These two steps can be performed in either order).
Press NOM% or EFF% to calculate the corresponding interest rate.
Example:
What is the effective interest rate for a Canadian mortgage with a nominal APR of 3.8%?
3.8 [NOM%]
2 [P/YR]
[EFF%] = 3.8361
What is the nominal rate of a US mortgage that is equivalent to this effective rate of 3.8361%?
Continuing from the previous example:
12 [P/YR]
[NOM%] = 3.7703
Code:
00 { 196-Byte Prgm }
01▸LBL "ICONV"
02▸LBL 00
03 CLMENU
04 "NOM%"
05 KEY 1 XEQ 01
06 "EFF%"
07 KEY 2 XEQ 02
08 "P/YR"
09 KEY 3 XEQ 03
10 "PER"
11 FC? 02
12 ├"•"
13 KEY 4 XEQ 04
14 "CON"
15 FS? 02
16 ├"•"
17 KEY 5 XEQ 05
18 MENU
19 STOP
20 GTO 00
21▸LBL 01
22 FS?C 22
23 GTO 07
24 RCL "EFF%"
25 100
26 ÷
27 LN1+X
28 FS? 02
29 GTO 11
30 RCL "P/YR"
31 ÷
32 LASTX
33 X<>Y
34 E↑X-1
35 ×
36▸LBL 11
37 100
38 ×
39▸LBL 07
40 STO "NOM%"
41 VIEW "NOM%"
42 RTN
43▸LBL 02
44 FS?C 22
45 GTO 08
46 RCL "NOM%"
47 100
48 ÷
49 FS? 02
50 GTO 12
51 RCL "P/YR"
52 ÷
53 LASTX
54 X<>Y
55 LN1+X
56 ×
57▸LBL 12
58 E↑X-1
59 100
60 ×
61▸LBL 08
62 STO "EFF%"
63 VIEW "EFF%"
64 RTN
65▸LBL 03
66 FS?C 22
67 STO "P/YR"
68 VIEW "P/YR"
69▸LBL 04
70 CF 02
71 RTN
72▸LBL 05
73 SF 02
74 END