+- HP Forums (https://www.hpmuseum.org/forum)
+-- Forum: HP Software Libraries (/forum-10.html)
+--- Forum: General Software Library (/forum-13.html)
+--- Thread: (12C) Distance Speed Time (/thread-21720.html)
(12C) Distance Speed Time - Gamo - 05-11-2024 07:57 AM
Recently I often do the bicycle exercise and I only have two data for
my cycling activity which is the Distance and Time. I like to know my
average speed and this program for the HP-12C will find the
Distance, Speed or Time.
--------------------------------------------------------------------
Since HP-12C doesn't have Lables I'll use Store Register 1, 2 and 3
R1 for Distance
R2 for Speed
R3 for Time
Input Instructions:
Input Two Known Variable to R1, R2 or R3
Input 0 for the "Unknown Variable" to R1, R2 or R3
--------------------------------------------------------------------
For the " Time " input is the same as the Degree Minute Second
instruction on HP-11 or HP-15C
Time Input Example:
1 hour 25 minute 30 second input as 1.2530
45 minute 15 second input as 0.4515
----------------------------------------------------------------------
Example: FIX 4
Distance is 15 km
Time is 36 minute
What is the Speed ?
15 [STO] 1 // Distance
0 [STO] 2 // Unknown Speed
0.36 [STO] 3 // Time
[R/S] Answer for the Speed is 25 km/h
---------------------------------------------
Speed is 25 km/h
Time is 30 minute
What is the Distance?
0 [STO] 1
25 [STO] 2
0.3 [STO] 3
[R/S] Answer for the Distance is 12.5 km
----------------------------------------------
Program:
Quote:01 RCL 1
02 X=0
03 GTO 10
04 RCL 2
05 X=0
06 GTO 10
07 RCL 3
08 X=0
09 GTO 47 // Line 01 to 09 for Distance, Speed or Time routine direction
10 RCL 3
11 INTG
12 STO 4
13 LSTx
14 FRAC
15 ENTER
16 EEX
17 2
18 x
19 INTG
20 STO 5
21 LSTx
22 FRAC
23 EEX
24 2
25 x
26 ENTER
27 6
28 0
29 ÷
30 RCL 5
31 +
32 6
33 0
34 ÷
35 RCL 4
36 + // Line 10 to 36 to convert time to decimal degree
37 RCL 2
38 X=0 // Test if unknow Speed Goto Line 42
39 GTO 42
40 x // Calculate Distance
41 GTO 00
42 X<>Y
43 RCL 1
44 X<>Y
45 ÷ // Calculate Speed
46 GTO 00
47 RCL 1
48 RCL 2
49 ÷
50 ENTER
51 INTG
52 STO 4
53 -
54 6
55 0
56 x
57 ENTER
58 INTG
59 STO 5
60 -
61 6
62 0
63 x
64 INTG
65 EEX
66 4
67 ÷
68 RCL 5
69 EEX
70 2
71 ÷
72 +
73 RCL 4
74 + // Line 47 to 74 Calculate and Convert Decimal to H.MS
Gamo 5/2024
RE: (12C) Distance Speed Time - Gamo - 05-12-2024 09:37 AM
Few more example.
Cycling distance is 35.08 km and took 2 hour 2 minute and 15 second
►What is the Average Speed?
►If to take 1 hour 30 minute What is the Average Speed?
►If the speed is 25 km/h How long it take to cover 35.08 km?
35.08 [STO] 1 // Input Distance
0 [STO] 2 // Unknown Speed
2.0215 [STO] 3 // Input Time
⁕[R/S] 17.2172 ≈ 17.2 km/h // Average Speed Result
1.3 [STO] 3 // Change Time Input
⁕[R/S] 23.3867 ≈ 23.4 km/h // Update the Average Speed
25 [STO] 2 // Input new data for Speed
0 [STO] 3 // Unknow Time
⁕[R/S] 1.2411 ≈ 1 hour 24 minute 11 Second // Update Time Result
Gamo 5/2024
RE: (12C) Distance Speed Time - Gamo - 05-17-2024 05:25 AM
My daily cycling exercise is getting better considering the distance versus time.
Since then, I always do 15 km distance with various average speeds.
My best time so far only took 36 minute to finish 15 km with this data
what is the average speed?
15 [STO] 1
0.36 [STO] 3
0 [STO] 2
[R/S] Display Average Speed answer is 25 km/h
If I want to spend less time cycling for 35 minute
what average speed I have to do?
While previous data still there
0.35 [STO] 3
[R/S] 25.7143 ≈ 25.7 km/h
If I speed up my cycling speed to 26 km/h
How long it will take to finish 15 km?
26 [STO] 2
0 [STO] 3
[R/S] 0.3436 Time is 34 minute 36 second
Gamo
RE: (12C) Distance Speed Time - Gamo - 05-20-2024 11:59 AM
Streamline this program from post #1
Quote:01 6
02 0
03 STO 6
04 RCL 3
05 X=0
06 GTO 41
07 INTG
08 STO 4
09 LSTx
10 FRAC
11 ENTER
12 EEX
13 2
14 x
15 INTG
16 STO 5
17 LSTx
18 FRAC
19 EEX
20 2
21 x
22 ENTER
23 RCL 6
24 ÷
25 RCL 5
26 +
27 RCL 6
28 ÷
29 RCL 4
30 +
31 RCL 2
32 X=0
33 GTO 36
34 x
35 GTO 00
36 X<>Y
37 RCL 1
38 X<>Y
39 ÷
40 GTO 00
41 RCL 1
42 RCL 2
43 ÷
44 ENTER
45 INTG
46 STO 4
47 -
48 RCL 6
49 x
50 ENTER
51 INTG
52 STO 5
53 -
54 RCL 6
55 x
56 INTG
57 EEX
58 4
59 ÷
60 RCL 5
61 EEX
62 2
63 ÷
64 +
65 RCL 4
66 +
Gamo
RE: (12C) Distance Speed Time - Gamo - 09-30-2024 09:59 AM
Program updated form Post #1 and Post #4
Instead of using the Storage Register 1, 2 and 3
This program will use the TVM buttons for quicker data input.
Distance use [ n ]
Speed use [ i ]
Time use [ PV ]
--------------------------------------------------
Use same program as on Post #1 or Post #4
Instead of [RCL] 1 change to [RCL] [ n ]
Instead of [RCL] 2 change to [RCL] [ i ]
Instead of [RCL] 3 change to [RCL] [ PV ]
--------------------------------------------------
Example Usage:
Distance is 23.51 km
Time is 34 minute and 24 second
what is the Speed ?
23.51 [ n ] input Distance
0.3424 [ PV ] input Time
0 [ i ] Unknown Speed
[R/S] answer for Speed is 41.01 km/h
Gamo 9/2024