Happy Pi Day! - Printable Version

Code:


%%HP: T(3)A(R)F(.);

DIR

  PId

  \<< PUSH RAD -105 CF -3 CF DUP .653 * 1.74 + IP R\->I DUP 2 MOD + DUP 4 * OVER DUPDUP 1 - 1

    FOR i i SQ SWAP / PICK3 + ROT SWAP -1

    STEP INV NIP UNROT + 1 - 3 0 UNROT

    FOR i i INV i 2 - INV - + -4

    STEP - 4 * EXPAND \->STR "/" " " SREPL DROP "'" "" SREPL DROP OBJ\-> DUP SIZE R\->I ALOG OVER - PICK3 * SWAP IQUOT + \->STR DUP HEAD -51 FC? { "." } { "," } IFTE + SWAP TAIL + 1 ROT 2 + SUB POP

  \>>

  PIn

  \<< PUSH RAD -105 CF -3 CF DUP 4 * OVER DUPDUP 1 - 1

    FOR i i SQ SWAP / PICK3 + ROT SWAP -1

    STEP INV NIP UNROT + 1 - 3 0 UNROT

    FOR i i INV i 2 - INV - + -4

    STEP - 4 * EXPAND \->STR "/" " " SREPL DROP "'" "" SREPL DROP OBJ\-> DUP SIZE R\->I UNROT PICK3 ALOG OVER - PICK3 * SWAP IQUOT + \->STR DUP HEAD -51 FC? { "." } { "," } IFTE + SWAP TAIL + 1 ROT .8 * 2 + SUB POP

  \>>

  PIdLF

  \<< PUSH RAD -105 CF -3 CF DUP 2 + 'DIGITS' STO .653 * 1.74 + IP R\->I DUP 2 MOD + DUP 4 * OVER DUPDUP 1 - 1

    FOR i i SQ SWAP FDIV PICK3 FADD ROT SWAP -1

    STEP FINV NIP UNROT + 1 - 3 0 UNROT

    FOR i i FINV i 2 FSUB FINV FSUB FADD -4

    STEP FSUB 4 FMULT ZZ\<-\->F DROP \->STR DUP HEAD -51 FC? { "." } { "," } IFTE + SWAP TAIL + DUP SIZE 1 - 1 SWAP SUB POP

  \>>

  PiM

  \<< PUSH RAD -105 CF -3 CF RAD DUP 2 / 5 DUP2 LOG / \->NUM CEIL 2 * 1 - R\->I ATN1X 16 * 239 ROT OVER LOG / \->NUM CEIL 2 * 1 - R\->I ATN1X 4 * - EXPAND \->STR "/" " " SREPL DROP "'" "" SREPL DROP OBJ\-> DUP SIZE R\->I ALOG OVER - PICK3 * SWAP IQUOT + \->STR DUP HEAD -51 FC? { "." } { "," } IFTE + SWAP TAIL + 1 ROT 2 + SUB POP

  \>>

  ATN1X

  \<< -1 UNROT 1 4 ROLLD OVER SQ PICK3 INV 4 ROLLD UNROT 3 SWAP

    FOR i OVER * DUP i * INV 5 PICK * 4 ROLL + UNROT 5 ROLL 4 ROLLD 2

    STEP DROP2 UNROT DROP2

  \>>

  PiMlf

  \<< PUSH RAD -105 CF -3 CF RAD DUP 2 + 'DIGITS' STO 2 / 5 DUP2 LOG / \->NUM CEIL 2 * 1 - R\->I ATN1Xlf 16 FMULT 239 ROT OVER LOG / \->NUM CEIL 2 * 1 - R\->I ATN1Xlf 4 FMULT FSUB ZZ\<-\->F DROP \->STR DUP HEAD -51 FC? { "." } { "," } IFTE + SWAP TAIL + DUP SIZE 1 - 1 SWAP SUB POP

  \>>

  ATN1Xlf

  \<< -1 UNROT 1 4 ROLLD OVER SQ PICK3 FINV 4 ROLLD UNROT 3 SWAP

    FOR i OVER FMULT DUP i * FINV 5 PICK FMULT 4 ROLL FADD UNROT 5 ROLL 4 ROLLD 2

    STEP DROP2 UNROT DROP2

  \>>

  DIGITS 52

END