Namir, Byte and REXX

[Massimo Gnerucci]

A blast from the past.

While browsing a 1996 backup of an old computer of mine, I found a directory with my dabbling exercises in Personal REXX 2.0 in the late 80ies.
And, lo and behold, there I found some examples - bundled with the program - from Namir's review of the product on BYTE.

Here's one:

Code:


/*______________________________________________________________________________*​/

/*ROOT.REX Accompanies the review, "Personal REXX" by Namir Clement Shammas, Byte, January 1988, page 167*/
/*______________________________________________________________________________*​/

/* Root seeing using Newton's method */
/* Personal REXX version */

NUMERIC DIGITS 10
NUMERIC FORM SCIENTIFIC

SAY 'Enter expression (of variable X) '
pull fstring

fstring = 'Y = '||fstring

SAY 'Enter guess and accuracy '
pull guess accr

diff = 2 * accr
iter = 0
MAXITER = 30

DO WHILE ABS(diff) > accr
  IF ABS(guess) > 1.0 THEN h = 0.01 * guess; ELSE h = 0.01
  SAY 'guess = ' guess
  diff = 2.0 * h * FF(guess) / (FF(guess + h) - FF(guess - h))
  guess = guess - diff
  iter = iter + 1
  IF iter > MAXITER THEN diff = 0
END

SAY ' '
SAY ' '
SAY 'Root = ' guess
SAY ' '
SAY 'Number of iterations = ' iter

EXIT

FF: PROCEDURE EXPOSE fstring
 arg X
 INTERPRET fstring
 /* variable Y is part of the interpreted fstring */
 RETURN Y

Serendipity... :)