HP Prime CAS programming

[compsystems]

An alternative way to define functions is to use the following template

PHP Code:

#cas
function name(args)
   ...
   return ...
end;
#end 


and you can even delete the directive #end

PHP Code:

#cas
function name(args)
   ...
   return ...
end; 


standard notation for CAS programs

PHP Code:

#cas
name(args):=
begin
   ...
   return ...
end;
#end 


or without #end

PHP Code:

#cas
name(args):=
begin
   ...
   return ...
end; 


Example with standard CAS notation.

PHP Code:

// fract1( 320, 240, 10 )
#cas
fract1( X_, Y_, Nmax ):=
BEGIN
    local x, y, z, c, j, w, h, res1, res2;
    //freeze;
    w := 2.7/X_;
    h := -1.87/Y_;
    res1 := []; 
    Y_ := Y_-1;
    for y from 0 to Y_ do
        c := -2.1+i*(h*y+0.935);
        for x from 0 to X_-1 do
            z := 0;
            for j from 0 to Nmax-1 do
                if abs( z := z^2+c )>2 then break; end;
            end;
            res1.append( pixon_p( x, y, 126*j+2079 ));
            c := c+w;
        end;
    end;
    wait(0);
    return "Done"
end;
#end 


As function

PHP Code:

// fract2( 320, 240, 10 )
#cas
function fract2( X_, Y_, Nmax )
    local x, y, z, c, j, w, h, res1, res2;
    //freeze;
    w := 2.7/X_;
    h := -1.87/Y_;
    res1 := []; 
    Y_ := Y_-1;
    for y from 0 to Y_ do
        c := -2.1+i*(h*y+0.935);
        for x from 0 to X_-1 do
            z := 0;
            for j from 0 to Nmax-1 do
                if abs( z := z^2+c )>2 then break; end;
            end;
            res1.append( pixon_p( x, y, 126*j+2079 ));
            c := c+w;
        end;
    end;
    wait(0);
    return "Done"
end;
#end 


With Python Syntax
// fract3( 320, 240, 10 )

PHP Code:

#cas
def fract3( X_, Y_, Nmax ):
    local x, y, z, c, j 
    for x in range( X_ ):
        for y in range( Y_ ):
            z = 0
            c = 2.7*x / X_-2.1 + i*( -1.87*y/Y_ + .935)
            for j in range( Nmax ):
                z = z*z + c
                if abs( z ) > 2:  # abs(z = z*z+c)>2:
                    break
            pixon_p( x, y, 255*20*j + 256 )
    wait(0)
    return "Done"
#end