(12C) Three Essential Function

[Gamo]

These update added more functions from the previous version.

1. Profit on Pricing
2. Geometric & Harmonic Mean
3. Combination
4. Permutation

All these funtions fit perfectly with 99 programming steps.

To go to each of these program: "Very easy to remember to each [GTO] programs"

f [PRGM] for Profit on Pricing
[GTO] 97 for Permutation
[GTO] 98 for Combination
[GTO] 99 for Geometric Harmonic Mean
-----------------------------------------------------------------
Example:

Combination 115C4
[GTO] 98 [R/S] initialize
f [∑] Clear Statistic Registers // do this steps for each new problem
115 [ENTER] 4 [R/S] 6,913,340

Permutation 115P4
[GTO] 97 [R/S] initialize
f [∑] Clear Statistic Registers // do this steps for each new problem
115 [ENTER] 4 [R/S] 165,920,160

Geometric & Harmonic Mean
[GTO] 99 [R/S] initialize
f [∑] Clear Statistic Registers // do this steps for each new problem
Data: 30, 10

30 [R/S] display Data #1
10 [R/S] display Data #2
0 [R/S] 17.3205 [X<>Y] 15
GM = 17.3250
HM = 15

Profit on Pricing: f [PRGM]
[n] Cost
[i] Price
[PV] Markup
[PMT] Margin
Input 0 for two unknown
Cost 8 Markup 25%
8 [n] 0 [i] 25 [PV] 0 [PMT] [R/S]
[RCL] [i] 10 // Answer Price
[RCL] [PMT] 20 // Answer Margin
---------------------------------------------
Program:

Code:


01    RCL [n]
02    X=0
03    GTO 18
04    RCL [i]
05    X=0
06    GTO 18
07    RCL [n]
08    RCL [i]
09    △%
10    [PV]
11    RCL [i]
12    RCL [n]
13    △%
14    CHS
15    [PMT]
16    CLx
17    GTO 00 // Profit on Pricing
18    RCL [PV]
19    X=0
20    GTO 28
21    1/x
22    EEX
23    CHS
24    2
25    +
26    1/x
27    [PMT]
28    RCL [PMT]
29    1/x
30    EEX
31    CHS
32    2
33    -
34    1/x
35    [PV]
36    RCL [n]
37    X=0
38    GTO 46
39    RCL [n]
40    RCL [PV]
41    %
42    +
43    [i]
44    CLx
45    GTO 00 // Profit on Pricing
46    RCL [i]
47    1
48    RCL [PV]
49    %
50    +
51    ÷
52    [n]
53    CLx
54    GTO 00 // Profit on Pricing
55    R/S
56    X=0
57    GTO 64
58    1/x
59    ENTER
60    LSTx
61    LN
62    ∑+
63    GTO 55
64    X-bar
65    X<>Y
66    1/x
67    X<>Y
68    e^x
69    GTO 55
70    R/S
71    ∑+
72    RCL 2
73    X=0
74    GTO 82
75    ÷
76    STOx1
77    1
78    STO-4
79    STO-2
80    RCL 4
81    GTO 72
82    RLC 1
83    GTO 70
84    R/S
85    X<>Y
86    STO 1
87    X<>Y
88    -
89    RCL 1
90    1
91    -
92    X≤Y
93    GTO 96
94    STOx1
95    GTO 90
96    RCL 1
97    GTO 84 // Permutation
98    GTO 70 // Combination
99    GTO 55 // GM & HM

Remark:
Each of these programs can run the same functions in the loop until
user change the program number. ( 97, 98 and 99) or f [PRGM]

Gamo 2/2020