(11C) TVM for HP-11C

[Gamo]

Interest Rate Solver Solutions for

1. Direct Reduction Loan Interest Rate with known [n, PV and PMT]
2. Sinking Fund Interest Rate with known [n, FV and PMT]

This program is adapted form the HP-55 Mathematic Programs

----------------------------------------
Procedure: [USER] mode [FIX] 2

Input n [A] PV or FV [ENTER] PMT [R/S] Your Guess [R/S]

For Suggested Guess

Problem with PV use [B]
Problem with FV use [D]

[C] Solve for Direct Reduction (Problem involve PV and PMT)
[E] Solve for Sinking Fund (Problem involve FV and PMT)
-------------------------------------------
Example:

1. Problem involve: n, PV and PMT

n=12
PV=5,000
PMT=500

12 [A] 5000 [ENTER] 179.86 [R/S] display 27.80

Use Suggested Guess: [B] display 3.06%

[C] display answer: 2.92%
----------------------------------------
2. Problem involve: n, FV and PMT

n=12
FV=5,000
PMT=400

12 [A] 5000 [ENTER] 400 [R/S] display 8.33

Use Suggested Guess [D] display 0.75%

[E] display answer: 0.74%
---------------------------------------
Program:

Code:


LBL A
STO 1  // n
R/S
÷ 
STO 3  // PV or FV ÷ PMT
R/S
EEX
2
÷
STO 2  // Your Guess
EEX
2
x
R/S
-------
LBL B  // Suggested Guess for problem PV / PMT
1/x
RCL 1
X^2
1/x
RCL 3
x
-
STO 2
EEX
2
x
RTN
------
LBL C  // Calculate i for problem PV /PMT
RCL 3
RCL 2
x
1
RCL 2
1
+
RCL 1
CHS
Y^X
STO 5
-
-
RCL 1
RCL 2
1/x
1
+
÷
1
+
RCL 5
x
1
-
RCL 2
÷
÷
STO+2
X^2
EEX
1
2
CHS
X≤Y
GTO C
RCL 2
EEX
2
x
RTN
------
LBL D  // Suggested Guess for problem FV / PMT
RCL 3
RCL 1
-
2
x
RCL 1
1
-
X^2
RCL 3
+
÷
STO 2
EEX
2
x
RTN
-------
LBL E  // Calculate i for problem FV / PMT
RCL 3
RCL 2
x
1
+
RCL 2
1
+
RCL 1
Y^X
STO 4
-
RCL 1
1
RCL 2
1/x
+
÷
1
-
RCL 4
x
1
+
RCL 2
÷
÷
STO+2
X^2
EEX
CHS
1
2
X≤Y
GTO E
RCL 2
EEX
2
x
RTN