Threaded Mode | Linear Mode

Jonathan Busby · (This post was last modified: 02-17-2021 10:52 PM by Jonathan Busby.)

Well, I found more absent-minded stupid associativity errors in the EBNF grammar for C- . Here is the corrected grammar :

Code:

program = declaration-list ;

declaration-list = declaration , { declaration } ;

declaration = var-declaration , fun-declaration ;

var-declaration = type-specifier , ID , [ "[" NUM "]" ] , ";" ;

type-specifier = "int" | "void" ;

fun-declaration = type-specifier , ID , "(" , params , ")" , compound-stmt ;

params = ( param , { "," , param } ) | void ;

param = type-specifier , ID [ "[" , "]" ] ;

compound-stmt = "{" , local-declarations , statement-list , "}" ;

local-declarations = { var-declaration } ;

statement-list = [ statement , { statement } ] ;

statement = expression-stmt | compound-stmt | selection-stmt | iteration-stmt | return-stmt ;

expression-stmt = [ expression ] , ";" ;

selection-stmt = if , "(" , expression , ")" , statement , [ "else" , statement ] ;

iteration-stmt =  while , "(" , expression , ")" , statement ;

return-stmt = "return" , [ expression ] , ";" ;

expression =  { var , "=" } , simple-expression ;

var = ID , [ "[" , expression , "]" ] ;

simple-expression = additive-expression , { relop , additive-expression } ;

relop = "<=" | "<" | ">" | ">=" | "==" | "!=" ;

additive-expression = term , { addop , term } ;

addop = "+" | "-" ;

term = factor , { mulop , factor } ;

mulop = "*" | "/" ;

factor = "(" , expression , ")" | var | call | NUM ;

call = ID , "(" , args , ")" ;

args = [ expression , { "," , expression } ] ;

Sorry for any inconvenience.

Regards,

Jonathan

NOTE #1 : I had also accidentally left out some non-superfluous non-terminals. Also, the "C-" assignment operator ( "=" ) is *right associative*, just like in full blown C. So, if that part of the grammar looks like it needs correcting, then just know that it doesn't because I intentionally made the EBNF version right associative to be fully compatible with the "C-" BNF grammar.

EDIT #1 : Incorporated changes mentioned in later posts into above EBNF grammar.