Calculator graphics drawing benchmark

[Werner]

I believe there's an error in the Casio fx-CG50 Python code:

Code:

    for x in range(0,380,s):
      i=s*randint(0,1)
      for x in range(i,188,2*s):
        line(x,y,x,y+s,color)

the inner loop should be 'for y in'.

Well, the DM42 is also a graphing calculator, is it not? A quick hack:

Code:

00 { 161-Byte Prgm }
01▸LBL "HIT"
02 LSTO "S"
03 CLLCD
04 RCL "ResY"
05 1
06 XEQ 14
07 LSTO "Y"
08▸LBL 02
09 RCL "ResX"
10 2
11 XEQ 14
12 LSTO "X"
13▸LBL 03
14 RCL "Y"
15 RCL "X"
16 RCL ST Y
17 RCL ST Y
18 RCL+ "S"
19 XEQ "LINE"
20 ISG "X"
21 GTO 03
22 ISG "Y"
23 GTO 02
24 RCL "ResX"
25 1
26 XEQ 14
27 STO "X"
28▸LBL 12
29 RCL "ResY"
30 2
31 XEQ 14
32 STO "Y"
33▸LBL 13
34 RCL "Y"
35 RCL "X"
36 RCL ST Y
37 RCL+ "S"
38 RCL ST Y
39 XEQ "LINE"
40 ISG "Y"
41 GTO 13
42 ISG "X"
43 GTO 12
44 RTN
45▸LBL 14
46 RCL "S"
47 %
48 RCL+ ST Z
49 1ᴇ3
50 ÷
51 X<>Y
52 DSE ST X
53 GTO 00
54 SIGN
55 +
56 RTN
57▸LBL 00
58 +
59 RAN
60 RCL× "S"
61 IP
62 +
63 END

using the following 'LINE' program
(a bit of overkill as it accepts both real and complex input, and works in RECT and POLAR modes)

Code:

00 { 76-Byte Prgm }
01▸LBL "LINE"
02 X<>Y
03 FC? 73
04 GTO 00
05 RECT
06 XEQ 00
07 POLAR
08 RTN
09▸LBL 00
10 CPX?
11 GTO 00
12 COMPLEX
13 X<> ST Z
14 COMPLEX
15 XEQ 00
16 COMPLEX
17 RTN
18▸LBL 00 @        (x0,y0) (x1,y1)
19 X<>Y
20 ENTER
21 RCL- ST Z @        (dx,dy)    (x1,y1)    (x0,y0)
22 COMPLEX @    (dx,dy)    dy    dx    (x1,y1)    (x0,y0)
23 X<0?
24 +/-
25 X<>Y
26 X<0?
27 +/- @        (dx,dy)    adx    ady
28 X>Y?
29 X<>Y
30 R↓ @            |max|    (x1,y1)    (x0,y0)
31 X>0?
32 STO÷ ST L @    delta    n    (x1,y1)    (x0,y0)
33 LASTX
34 R↓
35 IP
36 +/-
37 X<> ST Z
38▸LBL 05 @        (x0,y0)    (x1,y1)    -n    delta
39 PIXEL
40 RCL+ ST T
41 ISG ST Z
42 GTO 05
43 R↓
44 PIXEL
45 END

drawing in GrMod=3 (400x240), S=8 runs in 7 seconds. (on USB power)
the number of pixels drawn is 15000, so performance index 2143

Cheers, Werner