(15C)(DM15) - Convert Number from one Base to Another

[Thomas Klemm]

This is a verbatim translation of this (HP-67) Base Conversion program for the HP-15C:

Code:

   001 {    42 21 11 } f LBL A
   002 {       44  3 } STO 3
   003 {          33 } R⬇
   004 {       44  1 } STO 1
   005 {          36 } ENTER
   006 {       32  3 } GSB 3
   007 {       32  0 } GSB 0
   008 {       45  3 } RCL 3
   009 {       32  3 } GSB 3
   010 {       44  1 } STO 1
   011 {       45  3 } RCL 3
   012 {    42 21  0 } f LBL 0
   013 {       44  2 } STO 2
   014 {          30 } −
   015 {          34 } x↔y
   016 {       44  0 } STO 0
   017 {    42 21  1 } f LBL 1
   018 {       45  1 } RCL 1
   019 {          34 } x↔y
   020 {       45  2 } RCL 2
   021 {          10 } ÷
   022 {       43 44 } g INT
   023 {       43 20 } g x=0
   024 {       22  2 } GTO 2
   025 {          33 } R⬇
   026 {          20 } ×
   027 {          33 } R⬇
   028 {          20 } ×
   029 {    44 40  0 } STO + 0
   030 {          33 } R⬇
   031 {       22  1 } GTO 1
   032 {    42 21  2 } f LBL 2
   033 {       45  0 } RCL 0
   034 {       43 32 } g RTN
   035 {    42 21  3 } f LBL 3
   036 {           1 } 1
   037 {          30 } −
   038 {       43 13 } g LOG
   039 {       43 44 } g INT
   040 {           1 } 1
   041 {          40 } +
   042 {          13 } 10ˣ
   043 {       43 32 } g RTN

Examples

325₈ to base 3

325 ENTER
8 ENTER
3 A

21220.


1101₂ to base 8

1101 ENTER
2 ENTER
8 A

15.


Compared to your output, the original number and its conversion to decimal are missing.
But I am sure that you can modify this program according to your needs.

---

This is a mostly verbatim translation for the HP-41C:

Code:

01 LBL "BC"
02 STO 03
03 RDN
04 STO 01
05 ENTER^
06 XEQ 03
07 XEQ 00
08 RCL 03
09 XEQ 03
10 STO 01
11 RCL 03
12 LBL 00
13 STO 02
14 -
15 X<>Y
16 STO 00
17 LBL 01
18 RCL 01
19 X<>Y
20 RCL 02
21 /
22 INT
23 X=0?
24 GTO 02
25 RDN
26 *
27 RDN
28 *
29 ST+ 00
30 RDN
31 GTO 01
32 LBL 02
33 RCL 00
34 RTN 
35 LBL 03
36 1
37 -
38 LOG 
39 INT 
40 1
41 +
42 10^X
43 END

And here's the same for the HP-42S:

Code:

00 { 58-Byte Prgm }
01▸LBL "BC"
02 STO 03
03 R↓
04 STO 01
05 ENTER
06 XEQ 03
07 XEQ 00
08 RCL 03
09 XEQ 03
10 STO 01
11 RCL 03
12▸LBL 00
13 STO 02
14 -
15 X<>Y
16 STO 00
17▸LBL 01
18 RCL 01
19 X<>Y
20 RCL 02
21 ÷
22 IP
23 X=0?
24 GTO 02
25 R↓
26 ×
27 R↓
28 ×
29 STO+ 00
30 R↓
31 GTO 01
32▸LBL 02
33 RCL 00
34 RTN
35▸LBL 03
36 1
37 -
38 LOG
39 IP
40 1
41 +
42 10↑X
43 END