What comes next?

[Gil]

Thanks for the Mathologer video, Thomas.

Here is my version of the Gregory-Newton Interpolation formulae for the HP50G.

Argument:
A non-empty list,
the 1st number being always = f(0),
the 2nd being = f(1),
the 3rd being = f(2), etc.

Example :
{0 1 4 9} NextN

and the result will be:
{ 0 1 4 9 }
f(x): 'x^2'
f(4): 16

Don't forget :
to put a zero for the 1st element in the above example list if you expect to get x². Remember: first element in the list is always f(0), ie in this example 0²=0.

If you put {1 4 9} instead,
then the program supposes that f(0) = 1, f(1) = 4 and f(2) =9, whose solution is obviously not x².

Result for {1 4 9} NextN:
{ 1 4 9 }
f(x): 'x^2+2*x+1'
f(3): 16

Example of Mathologer
{1 2 4 8 16 31} NextN

and the result will be:
{ 1 2 4 8 16 31 }
:f(x): '1/24*x^4-1/12*x^3+11/24*x^2+7/12*x+1'
f(6): 57

Attention again: suppose that the sequence were
{0 1 2 4 8 16 31}

then {0 1 2 4 8 16 31} NextN:
will give the following output:
{ 0 1 2 4 8 16 31 }
f(x): '-1/720*x^6+7/240*x^5-29/144*x^4+37/48*x^3-467/360*x^2+17/10*x'
f(7): 56

From last example, calculate for instance f(2.5):
a) DROP
2.5 'x' STO
EVAL
and you get 2.8291015625
b) or
-105 CF
25 ENTER 10 /
'x' STO
EVAL
and you get '2897/1024'.

Code below slightly changed in comparison to previous versions

Code:


\<< "
Arg
{
 f(0) f(1) f(2)f(n)
}

Ex: 
{ 
0 1 4 9 16 24 
}


Result: f(n+1)
Here: 
30

" DROP DUP DUP DUP SIZE R\->I \-> L s
  \<< s 1 ==
    IF
    THEN DROP L 1 GET DUP FP 0 == { R\->I } IFT "f(x)" \->TAG
    ELSE 1 GET DUP FP 0 == { R\->I } IFT 1 \->LIST 2 s
      FOR i { } 2 s i 2 - -
        FOR j L j GET L j 1 - GET - +
        NEXT DUP 'L' STO 1 GET DUP FP 0 == { R\->I } IFT +
      NEXT -114 CF -105 CF 'x' PURGE 'L' STO 0 0 s 1 -
      FOR i L i 1 + GET DUP 0 ==
        IF
        THEN
        ELSE i R\->I DUP DUP DUP
          CASE 0 ==
            THEN 3 DROPN 1
            END 1 ==
            THEN DROP2 x
            END x 1 ROT 1 -
            FOR i x i R\->I - *
            NEXT SWAP ! /
          END EVAL *
        END +
      NEXT 1 s
      FOR i L i GET TYPE 0 ==
        IF
        THEN s 'i' STO -105 SF
        END
      NEXT EXPAN \->STR 11 14
      FOR i ".E-" i R\->I + "*0" SREPL DROP
      NEXT ".+" "+" SREPL DROP ".-" "-" SREPL DROP ".*" "*" SREPL DROP ".'" "'" SREPL DROP "." "." SREPL 0 ==
      IF
      THEN -105 CF
      END OBJ\-> EVAL EXPAN \->STR "+-" "-" SREPL DROP OBJ\-> "f(x)" \->TAG DUP EVAL s 'x' STO EVAL DUP FP 0 == { R\->I } IFT "f(" s R\->I + ")" + \->TAG 'x' PURGE
    END
  \>>
\>>