F distribution on the 41C

[Dieter]

(12-21-2015 07:24 PM)Dieter Wrote:  This is what I currently use in Excel for calculating the upper F integral.

Addendum: here is a slightly more compact version of the regularized Beta function. While in the previous implementation one loop calculates both the odd and even terms of the continued fraction, here is a version that computes them separately:

Code:

Function ibeta(ByVal x, ByVal a, ByVal b)

tiny = 1E-300
c = 1
d = 1 - (a + b) * x / (a + 1)
If (Abs(d) < tiny) Then d = tiny
d = 1 / d
h = d
k = 2

Do
   m = k \ 2
   r = x / ((a + k - 1) * (a + k))
   If k Mod 2 = 0 Then
      aa = m * (b - m) * r
   Else
      aa = -(a + m) * (a + b + m) * r
   End If
   c = aa / c + 1
   If (Abs(c) < tiny) Then c = tiny
   d = aa * d + 1
   If (Abs(d) < tiny) Then d = tiny
   d = 1 / d
   adj = c * d
   h = h * adj
   k = k + 1
Loop Until (adj = 1) Or (m > 200)

If m > 200 Then
   ibeta = -1
Else
   ibeta = h * x ^ a * (1 - x) ^ b / a / betaf(a, b)
End If

End Function

In this particular case I think the underflow tests (if abs(x)<tiny then x=tiny) follow an addition of 1, so maybe they can be replaced with "if x=0 then...". Maybe the floating point experts can comment on this.

Dieter