Fick Cardiac Output

[Eddie W. Shore]

Fick Cardiac Output Equations

The program FICK will calculate:

* CO: Cardiac Output (L/min)
* SV: Stroke Volume (ml)
* CI: Cardiac Index (L/(min/m^2))
* SI: Stroke Index (ml/m^2)

Given the following inputs:

* Ca: Arterial blood oxygen (O2) content percentage
* CvO2: Venous blood oxygen (O2) content percentage
* VO2: Oxygen compulsion (in ml per pure oxygen gas per minute, STPD)
* HR: Heart Rate in beats per minute (BPM)
* Height in cm
* Weight in kg

STPD: Standard Temperature Pressure Density

Conversion factors: 1 in = 2.54 cm, 12 in = 1 ft, 1 lb = 0.45359237 kg

Formulas:

CO = VO2 / (10 * (Ca - CvO2))
SV = CO * 1000/HR
CI = CO/BSA
SI = SV/BSA

BSA: body surface area, measured in cm^3. There are several formulas, but the Fick program uses the simple approximation formula:

BSA = √(weight * height)/60

HP Prime Program FICK

Code:

EXPORT FICK()
BEGIN
// Fick Cardiac Output
// HP 65, 1972
// EWS 2017-04-10

// inputs
LOCAL ca,cv,vo,hr,h,w;
INPUT({ca,cv,vo,hr,h,w},
"Fick Cardiac Output",
{"Ca O_2:","C_v O_2:","VO_2:","HR:",
"Height:","Weight:"},
{"Arterial blood (%)",
"Venous blood (%)",
"O_2 compulsion (ml/min)",
"Heart Rate (BPM)",
"Height (cm)",
"Weight (kg)"});

// calculation
LOCAL co:=vo/(10*(ca-cv));
LOCAL sv:=co*1000/hr;
// simple BSA
LOCAL bsa:=√(w*h)/60;
LOCAL ci:=co/bsa;
LOCAL si:=sv/bsa;

// output
PRINT();
PRINT("Cardiac Output (l/min)");
PRINT(co);
PRINT("Stroke Volume (ml)");
PRINT(sv);
PRINT("Cardiac Index (L/(min/m^2))");
PRINT(ci);
PRINT("Stroke Index (ml/m^2)");
PRINT(si);

END;

Example:

Inputs:



* Ca: 19%
* CvO2: 15%
* VO2: 250 ml/min
* HR: 64
* Height: 5 ft 11 in, 180.34 cm
* Weight 196 lb, 88.90410452 kg

Results:

* CO: 6.25 L/min
* SV: 97.65625 ml
* CI: 2.96158586825 L/(min/m^2)
* SI: 46.2747791914 ml/m^2

Source:

Hewlett Packard. HP-67/97 User’s Library Solutions: Cardiac Corvallis, OR 1976 pg. 20