android free app anomaly

[compsystems]

In the input line, it is not yet fully compatible with the function definition, please use the HPconnKit program editor or write directly to the program editor.

HOME MODE VERSUS MODE CAS

A significant difference is that in HOME mode, expressions on the right side of a variable can not contain symbols that do not contain a predefined value, or use system variables as F1 X L1 M1, another way is define subfunctions to transfer values.

Example

PHP Code:

// file euler1.hppprgm
// CAS MODE
#cas
  euler1():=
  begin
    local g,c,m,t;
    local vi,ti,vf,tf,iteration;
    local v;
    purge(g,c,m,t,vi,ti,vf,tf);
    v(t):= vi+(g-(c/m)*vi)*(t-ti);
    g:=9.81; c:=12.5; m:=68.1;
    vi:=0;
    ti:=0;
    iteration:=1;
    PRINT(); // clear terminal view (output)
    print("euler1");
    print("press [↓] for next iteration" );
    print("press [on] for exit" );
    wait(1);      
    for tf from 0 to 10 step 2 do
      PRINT(); // clear terminal view (output)
      print("iteration = "+iteration);
      vf:=v(tf);
      print("vi = "+vi+" m/s");
      print("ti = "+ti+" s");
      print("tf = "+tf+" s");
      print("vf("+tf+") = "+vf+" m/s");
      print("");
      vi:=vf;
      ti:=tf;
      iteration:=iteration+1; 
      wait();
    end;
    print("iterations finished" );
    return("done");
  end;
#end 


PHP Code:

// file euler2.hppprgm 
// HOME MODE
local g;c;m;t;
local vi;ti;vf;tf;iteration;
local v(t)
begin
    return vi+(g-(c/m)*vi)*(t-ti);
end;

export euler2()
begin
  purge(g,c,m,t,vi,ti,vf,tf);
  g:=9.81; c:=12.5; m:=68.1;
  vi:=0;
  ti:=0;
  iteration:=1;
  print; // clear terminal view (output)
  print("press [↓] for next iteration" );
  print("euler2");
  print("press [on] for exit" );
  wait(1);   
  for tf from 0 to 10 step 2 do
    print; // clear terminal view (output)
    print("iteration = "+iteration);
    vf:=v(tf);
    print("vi = "+vi+" m/s");
    print("ti = "+ti+" s");
    print("tf = "+tf+" s");
    print("vf("+tf+") = "+vf+" m/s");
    print("");
    vi:=vf;
    ti:=tf;
    iteration:=iteration+1; 
    wait();
  end;
  print("iterations finished" );
  return("done");
end;