Python to RPN converter

[Thomas Klemm]

While the syntax of hy is similar to Clojure we can still use a while-loop and mutate local variables.
This makes the translation from Python straight forward.
We can even break out of a loop.

I've translated a few of the other examples:

Celsius to Fahrenheit

Code:

(defn fahrenheit [celsius]
  (+ (/ (* 9 celsius) 5) 32))

Quadratic Equation

Code:

(defn qe [a b c]
  (setv
    p (/ b a -2)
    q (/ c a)
    D (sqrt (- (** p 2) q)))
  [(+ p D) (- p D)])

Greatest Common Divisor

Code:

(defn gcd [a b]
  (while (!= b 0)
    (setv 
      r (% a b)
      a b
      b r))
  a)

Factors of a Number

Code:

(defn factor [n]
  (setv p 2)
  (while (> n 1)
    (if (> (** p 2) n)
      (do
        (print n)
        (break)))
    (while (= (% n p) 0)
      (do
        (print p)
        (setv n (// n p))))
    (setv p (+ p 1))))

Circumference of an Ellipse

Code:

(defn ellipse [a b]
  (setv
    u 1
    v (/ b a)
    s (/ (+ 1 (** v 2)) 2)
    t 1)
  (while (= 0 0)
    (setv m (/ (+ u v) 2))
    (if (= m u)
      (break))
    (setv
      w (/ (- u v) 2)
      v (sqrt (* u v))
      u m
      s (- s (* t (** w 2)))
      t (* t 2)))
  (/ (* 2 pi a s) u))

---

It appears that print is handled as a function in hy.
Thus I had to extend the compiler a bit.
Otherwise translating the factor function would lead to errors.

It is mapped to AVIEW:

Code:

function = {
    # built-in
    'abs' : 'ABS',
    'int' : 'INT',
    'round' : 'RND',
    'print' : 'AVIEW',
    # math
(...)