smaller HP 82166A with 32-pin connector

[J-F Garnier]

(09-20-2021 04:47 PM)Klaus Overhage Wrote:  pyILPER contains a simulation of the HP-7470A plotter and can save the drawn image as a PDF. I wanted to try that out with the HP-41 BIRTH program from J-F Garnier. So as an intermediate step, a version for the Canon X-710 that uses the PANAME ROM was created. Since the plotter commands contained in this ROM are very similar to those of the HP plotter module, the changeover is almost done.

The BIRTH program was really fascinating, running on a HP-41 35 years ago ! The Canon (or Tandy) printer/plotter was a great and affordable device (even if a HP82166 converter was needed) for the non-professional.

As mentioned in my original article, BIRTH was an adaptation of a HP-85 program from the Games Pac, that nowadays can still be found here:
https://www.series80.org/Programs/HP85-G...index.html

Original HP-85 program, for your reference:

Code:

10 DIM R(17,2),N$[32]
20 PRINTER IS 2
30 CLEAR @ DISP "ENTER YOUR NAME, PLEASE";
40 INPUT N$
50 DISP "ENTER YOUR BIRTHDAY,(MMDDYY)";
60 INPUT Z
70 C=INT(LOG(Z)-7)*.01
80 RANDOMIZE Z*.6142253371
90 I=INT(RND*10)+7
100 U1,U2=-INF @ L1,L2=INF
110 FOR J=1 TO I
120 R(J,1)=RND
130 IF R(J,1)>U1 THEN U1=R(J,1)
140 IF R(J,1)<L1 THEN L1=R(J,1)
150 R(J,2)=RND
160 IF R(J,2)>U2 THEN U2=R(J,2)
170 IF R(J,2)<L2 THEN L2=R(J,2)
180 NEXT J
190 GCLEAR
195 U=U2
200 U2=U2+(U2-L2)/16
210 SCALE L1,U1,L2,U2
220 MOVE R(1,1),R(1,2)
230 FOR J=1 TO 25
240 R(I+1,1)=R(1,1)
250 R(I+1,2)=R(1,2)
260 FOR K=1 TO I+1
270 BEEP INT(RND*90),INT(RND*20)
280 DRAW R(K,1),R(K,2)
290 IF K>I THEN 320
300 R(K,1)=C*(R(K+1,1)-R(K,1))+R(K,1)
310 R(K,2)=C*(R(K+1,2)-R(K,2))+R(K,2)
320 NEXT K
330 NEXT J
340 MOVE L1,U @ LABEL "     "&N$
350 GOSUB 390
360 COPY
370 GOSUB 390
380 STOP
390 FOR I=1 TO 9
400 PRINT
410 NEXT I
420 RETURN
430 END

J-F