Sharp PC-1211/TRS-80 PC-1 Software

[Hollerith]

Here is the "Lander" program from the Games package. I chose this one because

I had already converted it.
It does not include special characters such as PI, SQRT, exponent
The instructions are only one page so I have OCRed it using FREEOCR.

Program

Code:


   10 " " PAUSE "ROCKET LANDING GAME"
   12 PAUSE "(C) 1980 TANDY CORP."
   20 PRINT "SHFT A TO INITIALIZE"
   30 PRINT "SHFT B TO RUN"
   32 PRINT "SHFT C TO REVIEW STATUS"
   40 PRINT "YOU WILL LAND OK IF"
   45 PRINT "YOUR ROCKET REACHES"
   50 PRINT "0 ALTITUDE WITH LESS"
   55 PRINT "THAN 10 UNITS VELOCITY."
   60 PAUSE "GOOD LUCK"
  100 "A" PAUSE "ROCKET LANDER START"
  110 USING "#####.##":V=-430:H=2678:F=725:T=0:X=F
  120 "C" PRINT "VEL=";V;" HT=";H
  130 PRINT "T=";T;" F=";F
  140 "B" INPUT "FUEL TO USE(0-75) ";P
  143 P=ABS P
  145 IF P>75 LET P=75
  150 IF P>F LET P=F
  155 F=F-P
  160 A=P*2000/(2000+F-X)-13:T=T+1
  170 H=H+V+A/2
  180 V=V+A
  190 IF F<=0 IF H>15 BEEP 1: PAUSE "OUT OF FUEL": GOTO 250
  200 IF H>0 GOTO 120
  210 IF ABS H<10 IF ABS V<10 BEEP 3: PRINT "LANDED IN ";T;" SEC": END 
  250 BEEP 5: PRINT "GOODBYE": END

Spaceship Lander

This program simulates a spacecraft landing on a planet. The
game starts with the craft descending toward the planet in
freefall at a starting height of about 2678 feet, and an initial
velocity of 430 feet/second toward the surface of the planet.

The object of the game is to land at zero velocity (height = 0
feet, velocity = 0 feet per second), by firing your rockets,
using the proper amount of fuel, at the right time. However, you
will land safely if your rocket reaches 0 altitude with less than
10 units of velocity.

You have a limited amount of fuel to accomplish your landing
(725 units). The maximum thrust you can request (in a single
one second burst) uses 75 units of fuel.
At the beginning of the game, the rocket provides an
acceleration of 1 ft/second, away from the surface, for each unit
of fuel. However, as fuel is burned and the remaining weight of
the spacecraft changes, the acceleration for a unit of fuel will
change accordingly. The gravity of the planet is 13 feet/second.

Instructions

1. Type CLOAD "LANDER" and press
ENTER .

2. When the ready display appears (>), press SHFT SPACE for
the Menu. Press ENTER to see each line.
SHFT A TO INITIALIZE (to set the landing conditions).
SHFT B TO RUN (to start the landing manuevers).
SHFT C TO REVIEW STATUS (of the spacecraft).

3. SHFT A will set up the program and create the landing
conditions. The spacecraft’s initial velocity and height is
shown on the display: VEL = -430.00 HT = 2678.00.
Press . The display will show the amount of time and
fuel availab|e:T = 00.0 F = 725.00.

4. Press SHFT B to start the landing procedure. The display
shows: FUEL TO USE (0-75). The computer is requesting
your fuel requirements for the first one-second burn. Enter
the amount of fuel to be burned (from 0 to 75 units).
The new velocity and height will be displayed. Press ENTER to
see the time and the remaining fuel. Press ENTER again, and
the computer will ask for the amount of fuel for the next
one-second burn.

You can display the ship’s status at any time by pressing
SHFT C. Continue the landing with SHFT B . You will land
successfully if you reach 0 height, with no more than 10
ft/second velocity. If you run out of fuel, you crash!

Happy Landing!


I have typed the program into a Sharp PC-1248 (worst keyboard ever), making changes for the smaller screen, and it runs OK.

On the PC-1 you run in DEF mode. On the PC-1248 ther is no DEF mode; use the DEF key instead of the SHFT key.