Bürgi's Kunstweg to Calculate Sines

[Thomas Klemm]

Reference
From: Jost Bürgi’s Method for Calculating Sines

Abstract

Quote:From various sources we know that the Swiss instrument maker and mathematician Jost Bürgi (1552-1632) found a new way of calculating any sine value.
Many mathematicians and historians of mathematics have tried to reconstruct his so-called “Kunstweg” (“skillful / artful method”), but they did not succeed.
Now a manuscript by Bürgi himself has been found which enables us to understand his procedure.
The main purpose of this article is to explain Bürgi’s method. It is totally different from the conventional way to calculate sine values which was used until the 17th century.

Division of a right angle into nine parts

Program to initialize the registers:

Code:

00 { 39-Byte Prgm }
01▸LBL "INIT"
02 CLRG
03 2
04 STO 01
05 4
06 STO 02
07 6
08 STO 03
09 7
10 STO 04
11 8
12 STO 05
13 9
14 STO 06
15 10
16 STO 07
17 11
18 STO 08
19 12
20 STO 09
21 END

Quote:The other nine cells are filled with an arbitrary series of natural numbers, for which Bürgi selects 2, 4, 6, 7, 8, 9, 10, 11, 12.
Bürgi does not mention that the numbers in column 1 are in principle his first approximations for sin 0° to sin 90° in relation to the value 12 for sin 90°.
Nor does he mention that the calculation will be shorter if the numbers correspond approximately to the ratio of the sine values of 10° to 90°.

Code:

00 { 42-Byte Prgm }
01▸LBL "STEP"
02 8
03 STO 00
04 2
05 STO÷ 09
06 RCL 09
07▸LBL 00
08 STO+ IND 00
09 RCL IND 00
10 DSE 00
11 GTO 00
12 2.009
13 STO 00
14 RCL 01
15▸LBL 01
16 STO+ IND 00
17 RCL IND 00
18 ISG 00
19 GTO 01
20 END

After the initialisation we perform 4 steps to get the values of column 5:

XEQ INIT
XEQ STEP
R/S
R/S
R/S

RCL 04
8273441

RCL 09
12871192

÷
0.64278747

Compare this to the correct value:

40
SIN
0.64278761


Division of a right angle into 90 parts

It's easy to adjust the program to do the same for \(n = 90\) to calculate the sines of all degrees from sin 1° to sin 90°.
To initialize the registers I use an approximation of the sines similar to before: \(\text{round}(12 \sin(x))\):

Code:

00 { 34-Byte Prgm }
01▸LBL "INIT-90"
02 CLRG
03 90
04 STO 00
05▸LBL 00
06 RCL 00
07 SIN
08 12
09 ×
10 .5
11 +
12 IP
13 STO IND 00
14 DSE 00
15 GTO 00
16 END

Code:

00 { 46-Byte Prgm }
01▸LBL "STEP-90"
02 89
03 STO 00
04 2
05 STO÷ 90
06 RCL 90
07▸LBL 00
08 STO+ IND 00
09 RCL IND 00
10 DSE 00
11 GTO 00
12 2.09
13 STO 00
14 RCL 01
15▸LBL 01
16 STO+ IND 00
17 RCL IND 00
18 ISG 00
19 GTO 01
20 END

SIZE 91

XEQ INIT-90
XEQ STEP-90
R/S
R/S

RCL 47
310796277956

RCL 90
424964111250

÷
0.73134712

Compare this to the correct value:

47
SIN
0.73135370

Here we performed only 3 steps instead of 4.
That's why the accuracy is not as good.
But we can also notice that the numbers get bigger than before.