(71B) FORTH questions

[Sylvain Cote]

(06-22-2023 05:13 PM)floppy Wrote:  Sylvain: "Software Developer Handbook" page 41 says, upload FTHUTILA and FTHUTILF: where are they (as LIF file)?

Using files from SDH LIF volume as is (with the 1BBBB bug in it) in a Emu71 + Virtual-IL setup ...

1. download the LIF volume file that Robert posted in one of the previous message → DEV-HB.DAT.txt
2. rename the file to DEV-HB.DAT
3. run ILPER
4. configure ILPER to use TCP-IP instead of the PIL-Box
5. configure ILPER to use the DEV-HB.DAT LIF volume
6. start ILPER
7. run EMU71
8. configure EMU71 virtual IL module to use TCP-IP
9. configure EMU71 to use the FORTH ROM image
10. configure EMU71 to use a 128K RAM module
11. start EMU71
12. CAT :TAPE should give you the following listing:
    
    Code:
    

       NAME    S TYPE   LEN    DATE    TIME 
STRINGLX     LEX     837 12/11/11 19:58 
KBD150       BASIC  1088 12/11/11 19:58 
PATTERN      LEX     171 12/11/11 19:59 
GEDIT        BASIC  1085 12/11/11 19:59 
KBD264       BASIC   932 12/11/11 19:59 
CUSTUTIL     LEX    1007 12/11/11 20:00 
FTHUTILA     TEXT   7424 12/11/11 20:00 
BREAKPT      LEX     365 12/11/11 20:01 
FTHUTILC     FORTH  4437 12/11/11 20:01 
FTHUTILF     TEXT  11520 12/11/11 20:03
13. PURGE FORTHRAM // optional: restart from scratch your FORTH environment
14. FORTH
15. " FTHUTILA:TAPE" ASSEMBLE
16. " FTHUTILF:TAPE" LOADF
17. TIME // get time and put value in X of the floating point stack
18. F. // display floating point stack X which is the time in seconds
19. BYE
    

Alternatively ...

my setup

• lifutils installed on macOS/linux and in my path.
• Using virtual machine provider (Parallels , VMware, etc) to run Windows 7 64-bit Pro
• Virtual-IL & EMU71 is installed in Windows
• Shared drive is activated and configured so I can stuff in macOS/Linux and use the output in Windows
  

Using the custom TIME patched file with in a Emu71 + Virtual-IL setup ...

1. save the following code in an ascii text file named -> timeasm.txt
   
   Code:
   

   
       FORTH
*                                TIMEASM
*                        FORTH TIME: Primitive

SAVEFP EQU #E717A           FORTH entry points:  Save FORTH pointers
GETFP  EQU #E71A5                                Recover FORTH pointers
STKLFT EQU #E7320                                Lift floating-point stack
CMPT   EQU #125B2          System entry points:  Read time
IDIV   EQU #0EC7B                                Full word integer divide
HXDCW  EQU #0ECB4                                Hex to decimal
FLOAT  EQU #1B322                                Integer to floating point
CLRFRC EQU #0C6F4                                Clear fractional part
DV2-12 EQU #0C4A8                                12-digit divide

* TIME : Read system clock in seconds; return result to X
       WORD 'TIME'
       GOSBVL SAVEFP
       GOSBVL STKLFT
       P=     5              *** workaround for bug 1084
       GOSBVL CMPT           C(W) = Time in hex 512ths of a second
*
ACLC24 A=C W                 Unsupported entry point. 12B79
       C=0 W
       P= 4
       LCHEX 2A3             C = 2A30000
       D=C W                 D = 2A30000 ( 24 hours in 512th's of a second )
*
       GOSBVL IDIV
       GOSBVL HXDCW
       A=C W
       GOSBVL FLOAT
       C=0 W
       P= 12
       LCHEX 512             C = 5.12
       GOSBVL DV2-12         A,B = Time*100
       GOSBVL CLRFRC         A,B = IP(Time*100)
       GOSUB TRUNCC
       C=C-1 X
       C=C-1 X               C = TIME
       SETHEX
       D0=(5) #2FBD0         X-Register
       DAT0=C W              X = TIME
       GOSBVL GETFP
       RTNCC

TRUNCC P= 0                  unsupported system utility at 12B4A
       LCHEX 00499           rounds 15-digit A,B to 12-digit C
       ?A<=C A
       GOYES TRUN20
       C=-C A
       ?A>=C A
       GOYES TRUN20
       C=0 W
       A=A+A A
       GOC TRUN10
       LCHEX F00
       C=A S
TRUN10 RTNCC
TRUN20 C=A W
       C=B M
       RTNCC

       END
   From the command line on macOS/Linux and in a folder that is shared with Windows:
   
2. lifinit -z -m cass v71time.dat 64
3. liflabel v71time.dat TAPE01
4. cat timeasm.txt | textlif TIMEASM | lifput v71time.dat
5. lifdir v71time.dat // should give you the following listing:
   
   Code:
   

   
Volume : TAPE01 , formatted : 22/06/23 15:00:00
Tracks: 2 Surfaces: 1 Blocks/Track: 256 Total size: 512 Blocks, 131072 Bytes
TIMEASM     TEXT         2048/2048     22/06/23 15:35:45
1 files (64 max), last block used: 17 of 512
   On Windows
6. run ILPER
7. configure ILPER to use TCP-IP instead of the PIL-Box
8. configure ILPER to use the v71time.dat LIF volume from the shared drive
9. start ILPER
10. run EMU71
11. configure EMU71 virtual IL module to use TCP-IP
12. configure EMU71 to use the FORTH ROM image
13. configure EMU71 to use a 128K RAM module
14. start EMU71
15. CAT :TAPE should give you the following listing:
    
    Code:
    

       NAME    S TYPE   LEN    DATE    TIME 
TIMEASM      TEXT   1792 06/22/23 15:07
16. PURGE FORTHRAM // optional: restart from scratch your FORTH environment
17. FORTH
18. " TIMEASM:TAPE" ASSEMBLE
19. TIME // get time and put value in X of the floating point stack
20. F. // display floating point stack X which is the time in seconds
21. BYE
    

edit 1: typo
edir 2: added environment info