CONVERT and variables for arguments

[epp]

By storing information in lists the code is shorter and modification is easier. The function, CNV(X), converts between units where X can be a real (18) or a unit (18_inch). Distance, Volume, and Weight have been implemented. Works under HOME and CAS.

RPN:
18 ENTER
CNV

TEXTBOOK:
CNV(18)

If the original number you are converting from is in units the answer will be in terms of units. For example, when converting 18 inches to feet we have

CNV(18_inch) -> 1.5_ft
CNV(18) -> 1.5

The following code can easily be modified to include other data types.

Code:


#pragma mode(separator(.,;) integer(h32))

// when changing menus update the following: cFr, cTo, unit, prog

cFr = {1,1,1};
cTo = {1,1,1};
iPr;

EXPORT CNV(x)
begin
  local unit = {
    {"mm", "cm", "m", "km", "inch", "ft", "yd", "mile"},
    {"ml", "l", "tsp", "tbsp", "qt", "inch^3", "ft^3"},
    {"g", "kg", "oz", "lb"}
  };
  local prog = {
    "Distance",
    "Volume",
    "Weight"
  };

  local t = type(x);
  local x0 = x;
  local uFr, uTo, n;

  if (t <> 0) and (t <> 9) then msgbox("Input must be REAL or UNIT"); return x; end;
  choose(iPr, "convert", prog);
  if (iPr == 0) then return x0; end;

  if (t == 0) then
    n := cFr[iPr];
    choose(n, "From", unit[iPr]);
    if (n == 0) then return x0; end;
    uFr := expr("1_" + unit[iPr,n]);
    x := x * uFr;
    cFr[iPr] := n;
  end;

  n := cTo[iPr];
  choose(n, "To", unit[iPr]);
  if (n == 0) then return x0; end;
  uTo := expr("1_" + unit[iPr,n]);
  x := convert(x, uTo);
  cTo[iPr] := n;

  if (t == 0) then x := x / uTo; else x; end;
end;

To place CNV on the command line choose

Toolbox > User > CNV > CNV

If you have previously visited this menu then choose Toolbox and keep pressing ENTER. Previous choices are saved by both the calculator and the CNV program.

Alternatively you can bind a key to insert "CNV" and then choose

Shift > Help > KEY

where KEY is the one you bind to CNV. The following code binds the Units key to CNV.

Code:


KEY K_Templ()
BEGIN
RETURN "CNV";
END;

On a small screen selecting menu items while running CNV can be a challenge. Instead use the rocker to navigate to the selection or use the keyboard and choose a number that corresponds to the selection. Implementing temperature conversions (Fahrenheit/Celsius) fail under firmware 8151 due to the lack of arithmetic support.