List Commands Library for 50g

[pier4r]

For the speed, thanks for sharing. I imagined that LSHUF would have been costly on a large list, but I thought on small list (less than 100 elements) the difference would be negligible. It seems not from what you wrote.

Anyway before speed, come effectiveness. So I am testing the effectiveness now, whather it takes in time.

For the "wouldn't it be better to test if the test works on a smaller input rather than waiting 8 hours for maybe nothing?" I agree. While I fall in this trap from time to time (damn me), I am slowly making progress so I already tested the test on one iteration with 4 elements building a list of size 6 (max 4096 possibilities). It took 25 minutes (I expected less, but I did not consider the LSHUF slow down as you wrote) and so from this I estimated 8 hours for 20 iterations.

It worked as expected, or better, it worked but the results of LSHUF (1.1.0d) are not that encouraging.


testing code

Code:


gpLSHUFtestArg
  \<<
    @execute to get the arguments
    { 10 20 30 40 } @list of elements
    
    @produce a list of N picks of elements that is the goal list
    1 6
    START 
      { 10 20 30 40 } @list of elements
      4 RAND * 1 + IP
      GET
    NEXT 
    6 \->LIST
    
    1 @number of simulations
  \>>
  
  gpLSHUFtestEng
  \<<
    {} "lvAttempsLSHUF" DROP
    {} "lvAttempsRAND"  DROP
    0  "lvListElemSize" DROP
    0  "lvListGoalSize" DROP
    0  "lvAttemps1Sim"  DROP
    0  "lvMaxAttempts"  DROP
    {} "lvListRes"      DROP
    0 "lvGoalFound"    DROP
    
    \->
    @input
    lvListElem
    lvListGoal
    lvSimNum
    
    @var
    lvAttempsLSHUF
    lvAttempsRAND
    lvListElemSize
    lvListGoalSize
    lvAttemps1Sim
    lvMaxAttempts
    lvListRes
    lvGoalFound
    
    \<<
      lvListElem SIZE 'lvListElemSize' STO
      lvListGoal SIZE 'lvListGoalSize' STO
      
      lvListElemSize lvListGoalSize ^ 'lvMaxAttempts' STO
    
      WHILE
        lvSimNum 0 >
      REPEAT
        
        @####
        @LSHUF attempt
        0 'lvAttemps1Sim' STO
        0 'lvGoalFound' STO
        WHILE
          lvAttemps1Sim lvMaxAttempts <
          lvGoalFound NOT
          AND
        REPEAT
          1 lvListGoalSize
          START
            lvListElem LSHUF HEAD
          NEXT
          lvListGoalSize \->LIST
          
          IF
            lvListGoal ==
              @if equal to the goal
          THEN
            1 'lvGoalFound' STO
          END
          
          'lvAttemps1Sim' 1 STO+
        END
        'lvAttempsLSHUF' lvAttemps1Sim STO+
        lvAttemps1Sim "AttempsLSHUF" \->TAG
          @dropping on the stack if the simulation is interrupted
        
        
        @####
        @RAND attempt
        0 'lvAttemps1Sim' STO
        0 'lvGoalFound' STO
        WHILE
          lvAttemps1Sim lvMaxAttempts <
          lvGoalFound NOT
          AND
        REPEAT
          1 lvListGoalSize
          START
            lvListElem 
            lvListElemSize RAND * 1 + IP
            GET
          NEXT
          lvListGoalSize \->LIST
          
          IF
            lvListGoal ==
              @if equal to the goal
          THEN
            1 'lvGoalFound' STO
          END
          
          'lvAttemps1Sim' 1 STO+
        END
        'lvAttempsRAND' lvAttemps1Sim STO+
        lvAttemps1Sim "AttempsRAND" \->TAG
          @dropping on the stack if the simulation is interrupted
        
        'lvSimNum' 1 STO-
      END
      
      lvListGoal "listGoal" \->TAG
      lvMaxAttempts "MaxAttempts" \->TAG
      lvAttempsLSHUF "AttempsLSHUF" \->TAG
      lvAttempsRAND "AttempsRAND" \->TAG
    \>>
  \>>

21 iterations results (time is not the main focus)

AttempsLSHUF: { 4096. 4096. 4096. 4096. 4096. 4096. 4096. 4096. 4096. 4096. 4096. 4096. 4096. 4096. 4096. 4096. 4096. 4096. 4096. 4096. }
the one iteration done before hand is also 4096. So LSHUF 1.1.0d was never able to produce a solution before doing enough attempts to go through all the possibilities.

AttempsRAND: { 2018. 1663. 1779. 4096. 2131. 370. 342. 2049. 2220. 4096. 2832. 822. 4096. 1305. 4096. 3202. 1997. 3936. 612. 3866. }
The one iteration I had before returned 2574.
Those made by rand are a bit more... reasonable?

So if my test is not wrong, I would say that LSHUF 1.1.0d is not producing enough randomness (I am not sure if the sentence makes sense). Now I will install the last update of listExt and I will see if something change. The 50g can crunch for 8 hours more in the night. As I said it, test driven usage.

More source code (although I think it is not needed), as usual in my assembla RPL repo: https://app.assembla.com/spaces/various-...cMathDir.s