(12C) Resistors in Parallel

[Gamo]

Program that solve up to "Four Pair" of unequal value of "Resistors in Parallel"
and little add-on program that solve for one unknown out of two parallel resistors from your desire Total.

Procedure:

1st Program:
All resistors must be "unequal" in value.
Store each value from R0 to R7
[R/S]

2nd Program
Store R0 for known Total
Store R1 for one of the two known resistor.
To run first goto line 40
[R/S]

----------------------------------------------------

Example:

Program 1: FIX 4

What is the total with 4 resistors in parallel?
50, 65, 120 and 250

50 [STO] 0
65 [STO] 1
120 [STO] 2
250 [STO] 3
[R/S] 20.9565

------------------------------------------------------

Program 2: FIX 4

1st resistor is 50 and my desire total is 28.2608
What is the 2nd resistor value?

28.2608 [STO] 0
50 [STO] 1
[GTO] 40
[R/S] 64.9996 = 65

Program:

Code:


01 RCL 0
02 1/x
03 RCL 1
04 1/x
05  +
06 RCL 2
07 X=0
08 GTO 37
09 1/x
10  +
11 RCL 3
12 X=0
13 GTO 37
14 1/x
15  +
16 RCL 4
17 X=0
18 GTO 37
19 1/x
20  +
21 RCL 5
22 X=0
23 GTO 37
24 1/x
25  +
26 RCL 6
27 X=0
28 GTO 37
29 1/x
30  +
31 RCL 7
32 X=0
33 GTO 37
34 1/x
35  +
36 GTO 38
37 X<>Y
38 1/x
39 GTO 00
--------------------------------------
40 RCL 0
41 RCL 1
42  x
43 RCL 1
44 RCL 0
45  -
46  ÷

Gamo

[Albert Chan]

Hi Gamo

Dieter had a better program, with more accuracy by doing R = R1 R2 / (R1 + R2)

Quote:What is the total with 4 resistors in parallel?
50, 65, 120 and 250

There is no need for more code. Just keep running each pair in parallel.

Parallel of 50, 65, R = 50*65/(50+65) = 28.261
"Add" 120, R = 120*28.261/(120+28.261) = 22.874
"Add" 250, R = 250*22.874/(250+22.874) = 20.957 (total of 4 resister in parallel)

Quote:1st resistor is 50 and my desire total is 28.2608
What is the 2nd resistor value?

Again, no need for more code. Remove a resister from total R, just negate the resister.

R1 = -50*28.2608/(-50+28.2608) = 65.000

[Thomas Klemm]

Or then we can use the method described by Sam Levy in his article EE calculations, some not obvious:

Quote:Resistive Dividers
When calculating from known resistors, enter the lower resistor repeatedly.

• Key in the top resistor, and add, the result is the total resistance,
• then divide, the result is the fractional output voltage of the divider.
• Then multiply and subtract to see the output resistance from the divider tap.
  

This leaves us with a program that consists of just the 4 arithmetic operators:

Code:

+
÷
×
-

Example:

50 ENTER ENTER ENTER
65 R/S
28.2609

Kind regards
Thomas

---

This method uses:

\(R_1 - \frac{R_1^2}{R_1 + R_2} = \frac{R_1 R_2}{R_1 + R_2}\)

[Gamo]

Thanks to Albert and Thomas

Many good varieties of ways to solve this type of problem.

Gamo

[Dieter]

(10-25-2018 12:50 PM)Albert Chan Wrote:  Dieter had a better program, with more accuracy by doing R = R1 R2 / (R1 + R2)

Here is how you can do it on the 12C:

Code:

01 ENTER
02 ENTER
03 R↓
04 R↓
05 X<>Y
06 x
07 X<>Y
08 LstX
09 +
10 ÷

As already pointed out, this is all you need for both calculations:

Add up parallel resistors: enter resistor values, one ofter another, and press [R/S]
Simply think of [R/S] as an "add resistor" key.

Find the required resistor for a given total: enter resistors as before, finally enter the desired total and press [CHS] [R/S] [CHS]

Example 1:
Two, three, four or more resistors in parallel.

50 [ENTER] 65 [R/S] => 28,26
120 [R/S] => 22,87
250 [R/S] => 20,96

Example 2:
Find the missing resistor.
Assume you have 100 and 220 Ω, and a total of 50 Ω is required.

100 [ENTER] 220 [R/S] => 68,75
50 [CHS] [R/S] [CHS] => 183,33

Or for Gamo's example:
50 [ENTER] 28,2608 [CHS] [R/S] [CHS] => 65

Dieter