(12C) ARM Term if Renewed

[Eddie W. Shore]

Situation: ARM Mortgage has one rate adjustment. The mortgage calls for the payment to remain the same for the entire mortgage, even after the rate adjustment. How long will it take to pay off the mortgage? Specifically, how long will it take after the rate is adjusted (ARM term)?

Example 1:

Original term: 30 years ( n = 360 )
Interest rate: 6% ( i = 6/12 )
The interest rate scheduled to increase 0.25% in 4 years.

HP 12C Procedure

Any loan amount will do for this problem. We'll use $1 for the loan amount in this example since we're only concerned with the ARM term.

Keystrokes:

(FIX 4 is set)

1. Find the payment of the original mortgage.

Clear Finance Registers: [ f ] [ x<>y ] (CLEAR FIN)
1 [ PV ]
30 [ g ] (12x) [ n ]
6 [ g ] (12÷) [ i ]
[PMT] (Result: -0.0060)

2. Determine the balance of the mortgage at the date when the mortgage is adjusted (4 years).

4 [ g ] (12x) [ n ]
[ FV ] (Result: -0.9461)

3. Transfer the balance to the new mortgage amount and enter the adjusted mortgage rate.

[CHS] [ PV ]
0 [ FV ]
[RCL] [ i ] 0.25 [ENTER] 12 [ ÷ ] [ + ] [ i ]
[ n ] (Result: 333.0000)

If the payment is kept the same, it would take another 333 payments to pay off the mortgage. The ARM Term is 333.

The total time it takes to pay the mortgage is:

Pre-Adjustment Term + ARM Term

In this case, 381 payments (48 + 333).

The program presented here will calculate the ARM term. This makes the assumption that the mortgage is only adjusted one time during its entire life. This is similar to looking up the financial table ARM Term If Renewed Table (refer to source).

HP 12C Program: ARM Term if Renewed

Code:


01  1      
02  PV
03  0
04  FV
05  PMT
06  RCL 1 
07  n
08  FV
09  CHS
10  PV
11  0
12  FV
13  RCL i
14  RCL 2
15  +
16  i 
17  n
18 GTO 00

(HP 12C Platinum: GTO 000)

Instructions:

Store the original number of periods in [ n ]
Store the original periodic interest rate in [ i ]
Store the number of months before the rate adjusts in R1.
Store the periodic adjustment (±r%) in R2.
Press [ R/S ]

Source:

Lincoln Title Company "Financial Conventional and ARM Payment Tables" Publication No. 493. Special Edition. Financial Publishing Company: Boston, MA. May 1985 ISBN 0-87600-493-1

Eddie

Link: https://edspi31415.blogspot.com/2019/02/...newed.html