(42S) Rate of Climb and Descent, Head and Cross Winds

[Eddie W. Shore]

Rate of Climb and Descent

The solver CLIMB creates a solver of the equation:

ROC = TAS * ALT / √(DIST^2 + ALT^2)

ROC: rate of climb, usually in ft/min
TAS: true airspeed of the airplane, usually in knots
ALT: (vertical distance) the change in elevation, take into the account the height of your airplane, the height of the mountain or obstacle to be cleared plus desired clearance height, usually in feet
DIST: (horizontal distance) distance to the mountain or obstacle to be cleared

For the solver to accurate, you must keep the units consistent (feet or nautical miles for distance, ft/min or knots for speed and rate of climb)

Conversion factors:

1 knot = 101.269 ft/min

1 nautical mile = 6076.12 ft

HP 42S/DM42/Free42 Solver program CLIMB


Code:


00 { 61-Byte Prgm }
01▸LBL "CLIMB"
02 MVAR "TAS"
03 MVAR "ALT"
04 MVAR "DIST"
05 MVAR "ROC"
06 RCL "TAS"
07 RCL× "ALT"
08 RCL "DIST"
09 X↑2
10 RCL "ALT"
11 X↑2
12 +
13 SQRT
14 ÷
15 RCL- "ROC"
16 .END.

Example:
TAS = 90 knots = 9114.21 ft/min
ALT = 5000 ft
DIST = 16 nautical miles = 97217.92 ft

Solve for ROC: 468.1328 ft/min

Link to download (climb_solver.raw): https://drive.google.com/open?id=1Zd_Gyj...5Gj_s1QBAS

Head Winds and Cross Winds

The program WINDS calculates the head wind and cross wind (right is positive, left is negative) given the following inputs:

D: reported wind direction
HDG: heading of the aircraft
V: compass magnetic variation, if any

The directions are entered in degrees, measured from true north, clockwise

K: reported wind velocity

Head wind:
HW = K cos(D - HDG - V)

Cross wind:
CW = K sin(D - HDG - V)

We can use the polar to rectangular conversion function with the following convention:

θ = D - HDG - V
r = K

HP 42S/DM42/Free42 Program WINDS

Code:


00 { 79-Byte Prgm }
01▸LBL "WINDS"
02 DEG
03 "WIND DIR?"
04 PROMPT
05 "HEADING?"
06 PROMPT
07 -
08 "COMP VAR?"
09 PROMPT
10 -
11 "WIND VELOCITY?"
12 PROMPT
13 →REC
14 "Y:CROSS X:HEAD"
15 AVIEW
16 STOP
17 RTN
18 .END.

Example:
Wind Direction: 30°
Heading of Aircraft: 350°
No compass adjustment
Wind Velocity: 20 knots

Results:
Y: cross winds: 12.8558 knots (from the right)
X: head winds: 15.3209 knots

Link to download (winds_head_and_cross.raw): https://drive.google.com/open?id=1RoIKgb...XmUw19e3wh

Source:

"Rate of Climb and Descent" and "Head Winds and Cross Winds" HP 65 Aviation Pac 1. Hewlett Packard, 1974

Blog link: http://edspi31415.blogspot.com/2020/01/h...b-and.html