(42S) RLC Circuits

[Eddie W. Shore]

The program RLC calculates:

(1) The total impedance across the entire circuit
(2) The phase angle, sometimes known as a power factor angle
(3) The total supply current

An RLC circuit is a circuit that connects one power supply to a resistor, an inductor, and a capacitor. The resistor, inductor, and capacitor can be connected in one of two ways: series or parallel. To calculate the total impedance (Z) and phase angle (θ), the rectangular to polar conversion function can be utilized.

Examples

Examples are rounded to five digits.


Series Circuit

Inputs:

SUPPLY VOLTAGE: 300 V
FREQUENCY: 70 Hz
RESISTANCE: 80 Ω
INDUCTOR: 0.09 H
CAPACITOR: 150 μF (150E-6)

Results:

IMPEDANCE (Z) ≈ 83.64599 Ω
PHASE ANGLE (θ) ≈ 16.97904°
CURRENT (I) ≈ 3.58654 A


Parallel Circuit

Inputs:

SUPPLY VOLTAGE: 240 V
FREQUENCY: 90 Hz
RESISTANCE: 60 Ω
INDUCTOR: 20 mH (20E-3)
CAPACITOR: 140 μF (140E-6)

Results:

IMPEDANCE (Z) ≈ 52.46010 Ω
PHASE ANGLE (θ) ≈ 29.05363°
CURRENT (I) ≈ 4.57491 A


Sources

“Impedance and Complex Impedance” https://www.electronics-tutorials.ws/acc...dance.html

“Parallel RLC Circuit Analysis” https://www.electronics-tutorials.ws/acc...rcuit.html

“Series RLC Circuit Analysis” https://www.electronics-tutorials.ws/acc...rcuit.html

Electronics Tutorials. AspenCore, Inc. 2024. Retrieved October 7, 2024 and October 17, 2024.

Code:

00 { 216-Byte Prgm }
01▸LBL "RLC"
02 "SUPPLY VOLTAGE?"
03 PROMPT
04 STO 01
05 "FREQUENCY?"
06 PROMPT
07 STO 02
08 "RESISTANCE?"
09 PROMPT
10 STO 03
11 "INDUCTOR?"
12 PROMPT
13 STO 04
14 "CAPACITOR?"
15 PROMPT
16 STO 05
17 DEG
18 2
19 STO 06
20 PI
21 STO× 06
22 RCL 02
23 STO× 06
24 "TYPE?"
25 AVIEW
26 PSE
27 "SERIES"
28 KEY 1 GTO 01
29 "PARA."
30 KEY 2 XEQ 02
31 MENU
32▸LBL 00
33 STOP
34 GTO 00
35▸LBL 01
36 CLMENU
37 EXITALL
38 RCL 06
39 RCL× 04
40 RCL 06
41 RCL× 05
42 1/X
43 -
44 RCL 03
45 →POL
46 STO 07
47 GTO 03
48▸LBL 02
49 CLMENU
50 EXITALL
51 RCL 06
52 RCL× 04
53 1/X
54 RCL 06
55 RCL× 05
56 -
57 RCL 03
58 1/X
59 →POL
60 1/X
61 STO 07
62▸LBL 03
63 "PHASE:"
64 AVIEW
65 PSE
66 VIEW ST Y
67 STOP
68 "IMPEADANCE:"
69 AVIEW
70 PSE
71 VIEW ST X
72 STOP
73 RCL 01
74 RCL÷ 07
75 "SUPPLY CURRENT:"
76 AVIEW
77 PSE
78 VIEW ST X
79 .END.