Post Reply 
41 Swap Disk Detective job: What does this program do?
11-21-2015, 11:05 AM (This post was last modified: 11-21-2015 05:15 PM by Ángel Martin.)
Post: #1
41 Swap Disk Detective job: What does this program do?
Those of you inclined to sleuth activities - would you take a look at the attached program and venture some conjectures as to its purpose and instructions?

It's included in the 41 Swap Disk collection, which as you probably know lacks any sensible index or TOC - this one in particular appears to be about Binary Mixtures (liquid/vapor equilibrium, perhaps using Van Laar or Wilson??) but I'm not sure about the scope and options.

Your guesses will be appreciated!

Code:

LBL "T"
STO 22
RCL 21
ENTER
RCL 34
*
STO 11
RCL 05
STO 23
RCL 07
STO 26
RCL 09
STO 27
RCL 22
XEQ "P"
RCL 11
*
STO 11
RCL 21
1
-
CHS
RCL 35
*
ENTER
STO 12
RCL 06
STO 23
RCL 08
STO 26
RCL 10
STO 27
RCL 22
XEQ "P"
RCL 12
*
RCL 11
+
RCL 13
/
1
-
RTN
LBL "P"
RCL 27
+
1/X
RCL 26
*
CHS
RCL 23
+
10^X
RTN
LBL "GAM"
1
-
CHS
STO 11
RCL 21
RCL 11
RCL 31
*
+
LN
CHS
STO 12
RCL 31
RCL 11
*
RCL 21
+
1/X
RCL 31
*
RCL 32
ENTER
RCL 21
*
RCL 11
+
1/X
RCL 32
*
-
RCL 11
*
RCL 12
+
E^X
STO 34
RCL 21
RCL 32
*
RCL 11
+
LN
CHS
STO 12
RCL 11
RCL 31
*
RCL 21
+
1/X
RCL 31
*
RCL 21
ENTER
RCL 32
*
RCL 11
+
1/X
RCL 32
*
-
RCL 21
*
CHS
RCL 12
+
E^X
STO 35
RTN
LBL "YEQ"
STO 21
XEQ "GAM"
RCL 14
STO 36
RCL 15
STO 37
XEQ "RAC1"
RCL 05
STO 23
RCL 07
STO 26
RCL 09
STO 27
RCL 25
XEQ "P"
RCL 13
/
RCL 21
*
RCL 34
*
STO 30
RTN
LBL "DISBIN"
"XF?"
PROMPT
STO 03
"XD?"
PROMPT
STO 01
"XW?"
PROMPT
STO 02
"FV?"
PROMPT
STO 04
"A1?"
PROMPT
STO 05
"B1?"
PROMPT
STO 07
"C1?"
PROMPT
STO 09
"A2?"
PROMPT
STO 06
"B2?"
PROMPT
STO 08
"C2?"
PROMPT
STO 10
"P MMHG?"
PROMPT
STO 13
"L12?"
PROMPT
STO 31
"L21?"
PROMPT
STO 32
FS? 21
SF 00
" 3"30 I.Y.P !"
RCL d
AVIEW
STO d
RCL 13
LOG
RCL 05
-
RCL 07
/
1/X
CHS
RCL 09
-
STO 14
RCL 13
LOG
RCL 06
-
RCL 08
/
1/X
CHS
RCL 10
-
STO 15
RCL 04
X=0?
XEQ 77
GTO 60
LBL 61
RCL 30
RCL 01
-
ENTER
RCL 01
RCL 18
-
/
CHS
ENTER
ENTER
1
-
/
CHS
FS? 00
XEQ 65
TONE a
"RMIN"
XEQ 88
"R?"
PROMPT
STO 00
RCL 03
RCL 02
-
RCL 01
ENTER
RCL 02
-
/
STO 16
"D"
XEQ 88
1
-
CHS
"W"
STO 17
XEQ 88
FS? 00
XEQ "L"
RCL 04
X=0?
GTO 78
RCL 01
RCL 00
1
+
/
RCL 03
RCL 04
/
-
STO 18
RCL 04
1
-
RCL 04
/
RCL 00
1
+
1/X
RCL 00
*
-
1/X
RCL 18
*
STO 18
LBL 78
XEQ "PLAT"
ADV
ADV
RCL 20
"NPT"
FIX 00
XEQ 88
RCL 19
"PLAT ALIM"
XEQ 88
" (MEL)?"  ;" \0C(MEL)?"
PROMPT
LOG
-.616
*
.17
+
1/X
RCL 20
*
"NPR"
XEQ 88
FS? 00
XEQ "L"
OFF
LBL 88
>"="
ARCL X
FS? 00
XROM 29,08
AVIEW
PSE
RTN
LBL 77
RCL 03
STO 18
XEQ "YEQ"
STO 22
GTO 61
LBL 60
.05
STO 38
.95
STO 39
XEQ "RAC2"
RCL 40
STO 18
GTO 61
LBL "RAC2"
RCL 38
STO 40
XEQ "XI"
STO 41
RCL 39
XEQ "XI"
STO 42
RCL 41
*
X>0?
GTO 13
LBL 14
RCL 39
RCL 39
RCL 38
-
RCL 42
RCL 41
-
/
RCL 42
*
-
STO 40
XEQ "XI"
STO 43
X=0?
GTO 15
ABS
1 E-3
X>Y?
GTO 15
RCL 43
RCL 42
*
X>0?
GTO 16
RCL 39
STO 38
RCL 42
STO 41
LBL 17
RCL 40
STO 39
RCL 43
STO 42
GTO 14
LBL 16
2
ST/ 41
GTO 17
LBL 13
"ERR"
PROMPT
LBL 15
RTN
LBL "RAC1"
RCL 36
STO 25
XEQ "T"
STO 28
RCL 37
STO 25
XEQ "T"
STO 29
RCL 28
*
X>0?
GTO 05
LBL 00
RCL 37
RCL 37
RCL 36
-
RCL 29
RCL 28
-
/
RCL 29
*
-
STO 25
XEQ "T"
STO 24
X=0?
GTO 06
ABS
1 E-5
X>Y?
GTO 06
RCL 24
RCL 29
*
X>0?
GTO 07
RCL 37
STO 36
RCL 29
STO 28
LBL 08
RCL 25
STO 37
RCL 24
STO 29
GTO 00
LBL 07
2
ST/ 28
GTO 08
LBL 05
"ERR COEF"
AVIEW
STOP
LBL 06
RTN
LBL "PLAT"
0
STO 20
RCL 02
STO 21
LBL 01
1
ST+ 20
RCL 21
XEQ "YEQ"
TONE 89
TONE 89
TONE 89
TONE 89
TONE 89
RCL 25
STO 15
XEQ 90
RCL 00
1
+
RCL 16
*
RCL 04
-
STO 22
RCL 30
*
RCL 17
ENTER
RCL 02
*
+
RCL 22
ENTER
RCL 17
+
/
STO 22
RCL 21
-
ABS
ENTER
1 E-4
X>Y?
GTO 99
RCL 22
STO 21
ENTER
RCL 18
X<=Y?
GTO 02
GTO 01
LBL 02
ADV
"ALIMENTATION"
FS? 00
XROM 29,08
AVIEW
ADV
FS? 00
XEQ "L"
RCL 20
STO 19
RCL 00
1
+
RCL 30
*
RCL 01
-
RCL 00
/
STO 21
LBL 03
1
ST+ 20
RCL 21
XEQ "YEQ"
TONE 47
TONE 47
TONE 47
TONE 47
TONE 47
RCL 25
STO 15
XEQ 90
RCL 30
ENTER
RCL 01
X<=Y?
GTO 89
1
RCL 00
1
+
RCL 30
*
RCL 01
-
RCL 00
/
STO 22
RCL 21
-
ABS
ENTER
1 E-4
X>Y?
GTO 99
RCL 22
STO 21
GTO 03
LBL 99
TONE 89
"R<RMIN"
TONE 47
PROMPT
LBL 87
>"="
ARCL X
FS? 00
XROM 29,08
AVIEW
RTN
LBL 90
ADV
"  PLAT"
FIX 00
ARCL 20
FS? 00
XROM 29,08
AVIEW
PSE
FIX 04
SF 13
"X"
RCL 21
XEQ 87
PSE
PSE
"Y"
RCL 30
XEQ 87
PSE
PSE
FIX 02
"DEGc"
ASTO T
"T="
ARCL 25
ARCL T
FS? 00
XROM 29,08
AVIEW
CF 13
FS? 00
XEQ "L"
LBL 89
RTN
LBL "L"
ADV
SF 12
""  ;"\01\01\01\01\01\01\01\01\01\01\01\01"
XROM 29,08
CF 12
RTN
LBL 65
"PRINTER ON"
PROMPT
RTN
LBL "XI"
STO 44
XEQ "YEQ"
RCL 30
RCL 03
RCL 04
/
-
STO 20
RCL 04
1
-
RCL 04
/
RCL 44
*
CHS
RCL 20
+
RTN
END


Attached File(s)
.txt  DISBIN.TXT (Size: 4.42 KB / Downloads: 8)
Find all posts by this user
Quote this message in a reply
11-21-2015, 12:07 PM
Post: #2
RE: 41 Swap Disk Detective job: What does this program do?
I noticed something related to pressure and temperature. OTOH, the string 'alimentation' shows up. HTH a bit.

d:-?
Find all posts by this user
Quote this message in a reply
11-22-2015, 03:57 AM
Post: #3
RE: 41 Swap Disk Detective job: What does this program do?
Hi there,
Whilst SLUFING the web I did find some references to old PPC & CHHU mag issues that may provide details, here is the web address:
http://www.hpmuseum.org/cgi-sys/cgiwrap/...gi?read=24
References and Resources:
Issue Title Author
PPC – LIF Storage Info (partial listing)
V9 N4 p42-44 Inside the Cassette Tape Marty Backe (7703)
V9 N6 p3 (letter) –short correction Bruce Bailey (7115)
V9 N6 p4 (letter) –short correction Marty Backe (7703)
V10 N6 p28-29 Inside the Cassette Tape – Revisited Tom Cadwallader (3502)
V10 N10 p9-11 HP82161A Cassette Utilities – DIRectory Backup Cary Enoch Reinstein (2046)
V11 N9 p55-56 TFSIZE – A Tape Data File Size Finder Larry Lavins (7310)
V12 N1 p6-8 Sizing and Reading Interchange Files John S. Chipman (8801)
V12 N1 p8-13 "Disco Skwid" – Disk Drive Limitations and workarounds Skwid
V12 N2 p15-17 Cassette Drive Problem Turner Morgan [283], (5766)
CHHU – LIF Storage Info
V1 N3 p5 Logical Interchange Files Michael Markov [3]
V1 N3 p12-14 HP-41 Mass Storage Utilities Michael Markov [3]
V2 N1 p28-29 HP-41 Mass Storage Utilities Part II Michael Markov [3]
V2 N3 p62-64 HP-41 Mass Storage Utilities Part III Michael Markov [3]
Swap Disks
Swap07 Lifdata.txt (LIF Directory Entry Info) Michael Markov [3]
The Internet
http://www.hpmuseum.org/ "HP Forum" discussion list, HP Calculator Museum, HP Calculator Classified Ads
http://ftp.ftp.math.jyu.fi/pub/hpil/ Archive of HP-IL and swap disk programs and files
http://ftp.fcext3.external.hp.com/dist/m...index.html HP’s freeware of LIF 2 DOS Utilities
---
Happy sleuthing DA
Find all posts by this user
Quote this message in a reply
Post Reply 




User(s) browsing this thread: 1 Guest(s)