Series of Resistors Current and Voltage drop for the HP-11C

//Berechnung des Stromes und der Spannungen bei einer Reihenschaltung von Widerständen
//Wenn man statt -1.009 -1.019 nimmt, Kann man 20 Register benutzen
//Starten des Programmes:
//[A] ausfuehren (im User-Mode)
//Wenn das Programm stoppt, die Widerstandswerte in die Register speichern, 
//Reihenfolge unwichtig, man kann auch unzusammenhaengende Register nehmen
//[R/S] druecken
//Wenn das Programm stoppt, dann die Spannung eingeben (einfach die Zahl eingeben)
//[R/S] druecken
//Ergebnis:
//Im T-Register(Stack) liegt der Strom, der durch die Widerstaende fliesst
//in den Registern ist der Spannungsabfall ueber dem betroffenen Widerstand verzeichnet


//Calculation of current and voltages at a circuit of resistors.
//Use -1.019 instead of -1.009 to use all 20 Registers
//Usage:
//Execute [A] (in user mode)
//once the program has stopped, store the values of the resistors in the registers
//press [R/S]
//once the program has stopped, key in the voltage
//press [R/S]
//Result:
//T-Stack contains the current
//The registers contain the voltage-drop over the resistor

//Beispiel/Example (in user mode)
//R1 = 32 Ohm; R2 =50 Ohm; R3 =80 Ohm;
//U = 23 Volt
//Press [A]
//wait.....
//Press 32 [STO] 0
//Press 50 [STO] 2
//Press 80 [STO] 4
//Press [R/S]
//wait.....
//Press 32
//Press [R/S]
//wait.....
//Press [R↑]      to view the T-Stack(the current)
//Press [RCL] 0 to view the voltage drop over R1
//Press [RCL] 2 to view the voltage drop over R2
//Press [RCL] 4 to view the voltage drop over R3

/*
Fragen/Questions→ khi1981 @ web.de  (remove the spaces)

Das Geheimnis hinter dem Programm:
U = R × I
Das Programm addiert alle Widerstandswerte zu einem Wert
Dann wird I = U/R gerechnet
Der Spannungsabfall an jedem Widerstand ist der Widerstandswert × I

The magic:
U=R×I
The program calculates the total resistance
With that it calculates I = U/R
The voltage drop = Resistand × I


Das Programm/The Program:
*/
Label A
        [Clear Reg]
        [R/S]   //Benutzer muss Widerstandswerte in Register laden

//Summe aller Widerstände berechnen
        [1]
        [CHS]
        [.]
        [0]
        [0]
        [9]
(optional
        [0]
        [1]
)
        [X⇔I]
        [0]
Label 1
        [ISG]
        [GTO] [2]

//U0 einlesen
        [R/S] //U0 in X schreiben

//Strom ausrechnen I=U/R
        [X⇔Y]
        [÷]

//Strom als Konstante in T schreiben
        [Enter]
        [Enter]
        [Enter]
        
//Alle Datenregister mit Strom multiplizieren
        [STO] [I]
        [1]
        [CHS]
        [.]
        [0]
        [0]
        [9]
(optional
        [0]
        [1]
)
        [X⇔I]
Label 3
        [ISG]
        [GTO] [4]
        [RTN]
//Ende des Programmes

Label 2
        [RCL][(i)]
        [+]
        [GTO][1]

Label 4
        [STO] [×] [(i)]
        [GTO] [3]