The Museum of HP Calculators The Museum of HP Calculators
This program is by Ken Delsnider and is used here by permission.
This program is supplied without representation or warranty of any kind. Ken Delsnider and The Museum of HP Calculators therefore assume no responsibility and shall have no liability, consequential or otherwise, of any kind arising from the use of this program material or any part thereof.
Program Name PISTA
Function Use to calculate the PI Station and PI Elevation of 2 intersection lines/Grades.
Where:
EL1 = Elevation of Point 1
STA1 = Station of Point 1
SL1 = Slope of First line
EL2 = Elevation of Point 2
STA2 = Station of Point 2
SL2 = Slope of Second line
PISTA = Point of Intersection Station
PIEL = Point of Intersection Elevation
00 { 144-Byte Prgm }
01>LBL "PISTA"
02 MVAR "EL1"
03 MVAR "STA1"
04 MVAR "SL1"
05 MVAR "EL2"
06 MVAR "STA2"
07 MVAR "SL2"
08 MVAR "PISTA"
09 MVAR "PIEL"
10 RCL "EL2"
11 RCL "EL1"
12 -
13 RCL "STA2"
14 RCL "SL2"
15 ×
16 -
17 RCL "STA1"
18 RCL "SL2"
19 ×
20 +
21 RCL "SL1"
22 RCL "SL2"
23 -
24 ÷
25 STO "X1"
26 RCL "SL1"
27 ×
28 RCL "EL1"
29 +
30 STO "PIEL"
31 RCL "X1"
32 RCL "STA1"
33 +
34 RCL "PISTA"
35 -
36 END
Go back to the software library
Go back to the main exhibit hall