HP Forums
(15C) Weibull Distribution Calculations - Printable Version

+- HP Forums (https://www.hpmuseum.org/forum)
+-- Forum: HP Software Libraries (/forum-10.html)
+--- Forum: General Software Library (/forum-13.html)
+--- Thread: (15C) Weibull Distribution Calculations (/thread-18878.html)

(15C) Weibull Distribution Calculations - Eddie W. Shore - 09-26-2022 04:38 AM

The Weibull probability density distribution function is:

f(x) = (b / Θ) * (x / Θ)^(b-1) * exp(-(x / Θ)^b)

with the lower tail cumulative distribution of (-∞ to x):

Area = 1 - exp(-(x / Θ)^b)

What follows are four calculations regarding the Weibull Distribution. In the following programs, store the following values first prior to running the programs:

R0 = x
R1 = b
R2 = Θ

Use whatever labels you like.

HP 15C Program: Lower Tail Probability - Weibull Distribution

CDF = 1 - exp(-(x/Θ)^b)

Code:
Keys:

LBL B
1
RCL 0
RCL÷ 2
RCL 1
y^x
CHS
e^x
-
RTN

Key Codes:

42, 21,12
1
45, 0
45, 10, 2
45, 1
14
16
12
30
43, 32

Example:
b = 1.96, Θ = 420
x = 300, result: 0.4038
x = 400, result: 0.5970
x = 500, result: 0.7552

HP 15C Program: Failure Rate - Weibull Distribution

FR = b/Θ * (x/Θ)^(b-1)

Code:
Keys:

LBL C
RCL 1
RCL÷ 2
RCL 0
RCL÷ 2
RCL 1
1
-
y^x
*
RTN

Key Codes:

42, 21, 13
45, 0
45, 10, 2
45, 0
45, 10, 2
45, 1
1
30
14
20
43, 32

Example:
b = 1.96, Θ = 420
x = 300, result: 0.0034
x = 400, result: 0.0045
x = 500, result: 0.0055

HP 15C Program: Mean of a Weibull Distribution

µ = (1/b)! * Θ

Code:
Keys:

LBL D
RCL 1
1/x
x!
RCL× 2
RTN

Key Codes:

42, 21, 14
45, 1
15
42, 0
45, 20, 2
43, 32

Example:
b = 1.96, Θ = 420
Result: 373.3720

HP 15C Program: Standard Deviation of a Weibull Distribution

σ = Θ * √((2/b)! - (1/b)!^2)

Code:
Keys:

LBL E
2
RCL 1
÷
x!
RCL 1
1/x
x!
x^2
-
√
RCL× 2
RTN

Key Codes:

42, 21, 15
2
45, 1
10
42, 0
45, 1
15
42, 0
43, 11
30
11
45, 20, 2
43, 32

Example:
b = 1.96, Θ = 420
Result: 198.2208

Sources:

HP55 Statistics Programs Hewlett Packard Company. Cupertino, CA. 1975

Ma, Dan. "The Weibull distribution" Topics in Actuarial Modeling. September 28, 2016. https://actuarialmodelingtopics.wordpress.com/2016/09/28/the-weibull-distribution/ Last Retrieved September 20, 2022.