(11C) Profit Pricing Solver

[Gamo]

Pricing calculation are based on Cost, Price, Markup and Margin.

Markup is based on cost and margin is based on selling price.

-----------------------------------------------

When entering data for business percentage calculations, results are calculated
based on data entered into specific memory registers. When pressed, the keys
used for these operations:

- store data.
- enter known data for variables used during calculations.
- calculate unknown variables based on stored data.

Program:
  Profit Pricing Solver.pdf (Size: 420.89 KB / Downloads: 56)

LBL E to Reset

1. Input two known variables and display shown 0 as an input.

2. Press the remain two unknown variables for answer.
First unknown variable return answer and press the same button once again then shown 0 as an input
and go ahead press the second unknown variable.

--------------------------------------------
Example: USER mode and FIX 2

Below example gave all results to check
with this program if all answers match.
Video Clip:
https://youtu.be/aQCbbOLwHgM

Cost = 8
Price = 10
Markup = 25
Margin = 20

If Price and Markup is unknown
8 [A] display 0 // Input Cost
20 [D] display 0 // Input Margin
[B] display 10 // Output Price
[B] display 0 // Store Price
[C] display 25 // Output Markup

If Cost and Margin is unkown
10 [B] display 0
25 [C] display 0
[A] display 8
[A] display 0
[D] display 20

To calculate between Markup and Margin only
25 [C] display 0
[D] display 20

20 [D] display 0
[C] display 25

***Special Procedure**
If Price and Margin is unknown this program
can go straight to find Markup first then Cost.

8 [A] display 0
25 [C] display 0
[D] display 20
[D] display 0
[B] display 10

--------------------------------------------

Remark:
This program can calculate Pricing Calculations in almost any order pairs.
The only pair that cannot be calculate is when you only known (Markup Margin) and look for (Cost Price).
In Pricing Calculation one must known either Cost or Price to determined all the remaining unknown variables.

Gamo

[Gamo]

Smaller program size version for HP-11C or 15C

This version not include the Reset routine.
------------------------------------------------

[A] Cost
[B] Price
[C] Markup
[D] Margin

Example: [USER] [FIX] 2

Cost = 8 and Margin = 20 find Price and Markup

8 [A] display 8.00 // Input Cost
20 [D] display 20.00 // Input Margin

If user want to know Markup right away simply press

[X<>Y] display 25.00 // Answer for Markup

[B] [R/S] display 10.00 // Output Price
----------------------------------------------
To Convert between Markup and Margin

Markup = 25 what is the Margin?

25 [C] display 25.00 [X<>Y] display answer 20.00 // Convert Markup to Margin
---------------------------------------------

Code:


LBL A  // Cost
GTO 1
LBL 6
RCL 2
RCL 4
%
-
LBL 1
STO 1
R/S
GTO 6
--------
LBL B  // Price
GTO2
LBL 7
RCL 1
RCL 3
%
+
LBL 2
STO 2
R/S
GTO 7
-------
LBL C  // Markup%
GTO 3
LBL 8
RCL 1
RCL 2
%CH
LBL 3
STO 3
EEX 2
x
LSTx
RCL 3
+
÷
STO 4
RCL 3 
R/S
GTO 8
--------
LBL D  // Margin%
GTO 4
LBL 9
RCL 2 
RCL 1
%CH
CHS
LBL 4
STO 4
EEX 2
x
LSTx
RCL 4
-
÷
STO 3
RCL 4
R/S
GTO 9

Gamo 6/19/2020

[Gamo]

Program on Post #2 Update

Just noticed that when user input Cost with Price and looking for Margin the

Margin routine will return "Error" on display due to the "Division by Zero"

when the Price input is 100.

Here is the updated routine start from LBL D

Code:


LBL D  // Margin%
GTO 4
LBL 9
RCL 2 
RCL 1
%CH
CHS
LBL 4
STO 4
EEX 2
x
LSTx
RCL 4
-
X=0 <------ If subtraction return zero 
GTO 9 <---- Goto Lable 9
÷
STO 3
RCL 4
R/S
GTO 9

Remark:
When price input is 100 the Margin routine give result right away no need to press [R/S]

Added on program can be use to find the "Profit Amount" on LBL E
Program Routine: [LBL] [E] [RCL] 2 [RCL] 1 [-] [RTN]

Gamo 8/2021