( Free42 ) Pricing Calculations

[Gamo]

This pricing calculations routine is adapted from my previous post on 11C, 12C and 41C

(11C) https://www.hpmuseum.org/forum/thread-12947.html

(12C) https://www.hpmuseum.org/forum/thread-13043.html

(41C) https://www.hpmuseum.org/forum/thread-14258.html

---------------------------------------------------------------------

This updated from the 41C "Profit on Pricing" version by added the Soft Menu keys,

Display Text for Input and Output with their variables name such as COST=12.25

with Tone for each input and output.

--------------------------------------------------------------------

For those who use the Free42 App or DM42 can download this RAW file provided in the

Dropbox Link below.

-------------------------------------------------------------------

User need to put the Soft Menu Key manually as shown below.

[COST] [PRICE] [MARK] [MARG] [$] [RESET]

ASSIGN "COST" to (Position as shown above)
ASSIGN "PRICE" to ..... (for the rest of Soft Menu Key as shown)

Here is the demostration clip: https://youtu.be/Q5jXIIHQHsg

RAW File: https://www.dropbox.com/s/71mncprd821s34...5.raw?dl=0

--------------------------------------------------------------------
Program:

00 { 244-Byte Prgm }
01 LBL "CST"
02 TONE 9
03 FS?C 22
04 GTO 01
05 FS?C 00
06 RCL 02
07 RCL 04
08 %
09 -
10 LBL 01
11 STO 01
12 "COST = "
13 ARCL ST X
14 AVIEW
15 RTN
---------------
16 LBL "PRC"
17 TONE 9
18 FS?C 22
19 GTO 02
20 FS?C 00
21 RCL 01
22 RCL 03
23 %
24 +
25 LBL 02
26 STO 02
27 "PRICE = "
28 ARCL ST X
29 AVIEW
30 RTN
-----------------
31 LBL "MU"
32 TONE 9
33 FS?C 22
34 GTO 03
35 RCL 03
36 FS?C 00
37 GTO 03
38 RCL 01
39 RCL 02
40 %CH
41 LBL 03
42 STO 03
43 100
44 x
45 LASTX
46 RCL 03
47 +
48 ÷
49 STO 04
50 RCL 03
51 "MARKUP = "
52 ARCL ST X
53 ⊢" %"
54 AVIEW
55 SF 00
56 RTN
-----------------
57 LBL "MAR"
58 TONE 9
59 FS?C 22
60 GTO 04
61 RCL 04
62 FS?C 00
63 GTO 04
64 RCL 02
65 RCL 01
66 %CH
67 +/-
68 LBL 04
69 STO 04
70 100
71 x
72 LASTX
73 RCL 04
74 -
75 ÷
76 STO 03
77 RCL 04
78 "MARGIN = "
79 ARCL ST X
80 ⊢" %"
81 AVIEW
82 SF 00
83 RTN
----------------
84 LBL "RESET"
85 FIX 02
86 BEEP
87 CF 00
88 CLX
89 STO 01
90 STO 02
91 STO 03
92 STO 04
93 "Business % "
94 ⊢"Ready ϋ"
95 AVIEW
96 RTN
-------------------
97 LBL "$"
98 TONE 9
99 RCL 02
100 RCL - 01
101 "PROFIT = "
102 ARCL ST X
103 ⊢" ϋ"
104 AVIEW
105 RTN
106 .END.
------------------
Example:

[RESET] display [ Businee % Ready ϋ ]

▶How to Calculate Gross Margins

If your business generated $400,000 in revenue for a year and
your gross profit is $200,000. What is the Gross Margin?

200000 [CST] display [ COST = 200,000.00 ]
400000 [PRC] display [ PRICE = 400,000.00 ]
[MAR] display answer [ MARGIN = 50.00 % ]
--------------------------------------------------
▶Markup & Margin Calculations

As a businessperson, you must set prices for goods and services you provide.
You also have to analyze prices and costs to insure your pricing is sufficient to produce a profit, but
not so high you’ll lose sales to competitors. Markup and margin are distinct, but
closely related measures that help you accomplish these tasks.

If an item costs $15 and the markup is 80 percent, what is the Selling Price and Profit?

15 [CST] display [ COST = 15.00 ]
80 [MU] display [ MARKUP = 80.00 % ]
[PRC] display answer [ PRICE = 27.00 ]
[$] display answer [PROFIT = 12.00 ϋ ]

If the price is $27 and the cost of the product is $15, what is the Margin.

Data from previous problem still in calculator simple press
[MAR] display answer [ MARGIN = 44.44 % ]
-----------------------------------------------
▶Conversions

Sometimes you may want to convert markup to margin or vice versa.

For instance, if the markup is 25% what is the margin?

25 [MU] display [ MARKUP = 25.00 % ]
[MAR] display answer [ MARGIN = 20.00 % ]
----------------------------------------------
Gamo 5/30/2020