Threaded Mode | Linear Mode

plore90 · (This post was last modified: 08-19-2024 10:48 PM by plore90.)

Hello everyone,
here I am again to present my latest program on the LIN-BAISTROW algorithm for HP67/97. The program can find the real and/or complex roots of a polynomial from the 3rd degree to the 7th degree with real coefficients. In the manual contained in the zip file, everything is explained with various examples.
I hope that the program can be useful to some of you, and in any case of interest to you for educational purposes on Hp-67/97. The program as usual is written in a very basic way and is contained on two magnetic cards. Refining and compacting it, I think that it could be possible to arrive at the solution up to 8th degree polynomials... Anyone can try it or test it on the emulators of HP67 and HP97 of mister LIMPID FOX that are free for their use. As usual I will be grateful to anyone who reports bugs or makes improvements to the program.
Thanks for your attention
Plore90
****************
UPDATE!!!!

In the new attachment there is the version of the program "Lin-Bairstow" published on "HP-67/97 EUROPE User's Group" which allows to find the real and complex roots of a polynomial up to degree 18.

****************

Thomas Klemm · 08-12-2024, 09:23 PM

Here are a few links for comparison:

(11C) Bairstow's Method
(15C) Bairstow's Method
Polynomials for the HP-41:
1°) Real Polynomials
g) Quadratic factors ( Bairstow's method )

The programs for the HP-11C and the HP-15C use the built-in L.R. (linear regression) function to solve the system of linear equations.
Therefore they can not be translated as is to the HP-67/97.
But it should be possible to back-port Jean-Marc Baillard's program for the HP-41C to the HP-67/97.

plore90 · 08-12-2024, 10:29 PM

Hi Thomas,
Thanks for the insight and suggestions...
plore90

Thomas Klemm · (This post was last modified: 08-14-2024 05:42 PM by Thomas Klemm.)

Here's a program that uses 112 lines.
A program B to solve the quadratic equation is also included.

Lin-Bairstow

This program is based on the Lin-Bairstow method to find the roots of a polynomial of degree \(n\):

\(P(x) = a_n x^n + a_{n-1} x^{n-1} + \cdots + a_2 x^2 + a_1 x + a_0 = 0\)

Code:

 31 25 11 : f LBL A

 00       : 0

 33 03    : STO 3

 33 04    : STO 4

 33 06    : STO 6

 33 07    : STO 7

 01       : 1

 00       : 0

 35 33    : h ST I

 31 25 00 : f LBL 0

 34 06    : RCL 6

 34 04    : RCL 4

 33 05    : STO 5

 34 02    : RCL 2

 71       : *

 51       : -

 34 03    : RCL 3

 33 04    : STO 4

 34 01    : RCL 1

 71       : *

 51       : -

 33 03    : STO 3

 34 24    : RCL (i)

 34 07    : RCL 7

 34 02    : RCL 2

 71       : *

 51       : -

 34 06    : RCL 6

 33 07    : STO 7

 34 01    : RCL 1

 71       : *

 51       : -

 33 06    : STO 6

 31 34    : f ISZ

 34 00    : RCL 0

 35 34    : h RC I

 32 71    : g x<=y

 22 00    : GTO 0

 34 03    : RCL 3

 34 07    : RCL 7

 71       : *

 34 04    : RCL 4

 34 06    : RCL 6

 71       : *

 51       : -

 34 05    : RCL 5

 34 06    : RCL 6

 71       : *

 34 04    : RCL 4

 34 07    : RCL 7

 71       : *

 51       : -

 34 05    : RCL 5

 34 03    : RCL 3

 71       : *

 34 04    : RCL 4

 32 54    : g x^2

 51       : -

 81       : /

 33 61 01 : STO + 1

 35 52    : h x<->y

 35 82    : h LSTx

 81       : /

 33 61 02 : STO + 2

 32 72    : g R->P

 31 24    : f RND

 31 61    : f x!=0

 22 11    : GTO A

 02       : 2

 33 51 00 : STO - 0

 01       : 1

 00       : 0

 35 33    : h ST I

 00       : 0

 41       : ENTER

 41       : ENTER

 41       : ENTER

 31 25 01 : f LBL 1

 35 53    : h Rv

 35 53    : h Rv

 34 24    : RCL (i)

 34 02    : RCL 2

 35 54    : h R^

 71       : *

 51       : -

 34 01    : RCL 1

 35 54    : h R^

 71       : *

 51       : -

 33 24    : STO (i)

 31 34    : f ISZ

 34 00    : RCL 0

 35 34    : h RC I

 32 71    : g x<=y

 22 01    : GTO 1

 35 22    : h RTN

Registers

\(\begin{matrix}
R_0 & 10 + n \\
R_1 & p \\
R_2 & q \\
R_3 & c = c_j \\
R_4 & {c}′ = c_{j+1} \\
R_5 & {c}'' = c_{j+2} \\
R_6 & b = b_i \\
R_7 & {b}′ = b_{i+1} \\
R_8 & \\
R_9 & \\
R_{10} & a_n \\
R_{11} & a_{n-1} \\
R_{12} & a_{n-2} \\
R_{13} & \cdots \\
R_{14} & \cdots \\
\end{matrix}\)

Quadratic Solver

This program solves the quadratic equation: \(T(x)=x^2+px+q=0\)

Code:

 31 25 12 : f LBL B

 34 01    : RCL 1

 02       : 2

 42       : CHS

 81       : /

 41       : ENTER

 41       : ENTER

 32 54    : g x^2

 34 02    : RCL 2

 51       : -

 31 54    : f sqrt

 51       : -

 35 52    : h x<->y

 35 82    : h LSTx

 61       : +

 35 22    : h RTN

Just be aware that this program can't find complex roots. Instead an Error will be displayed.
However it's easy to find the complex solutions. Just use:

CHS
\(\sqrt{x}\)

The solutions then are: \(Y \pm iX\)

Example

\(P(x)=2x^5-9x^4+15x^3+65x^2-267x+234=0\)

Insert coefficients

Code:

CL REG

2      STO 0

-9     STO 1

15     STO 2

65     STO 3

-267   STO 4

234    STO 5

P<>S

Initialization

Store \(10 + n\) in register \(0\) and initialize \(p = q = 1\).

Code:

15  STO 0

1   STO 1

    STO 2

Run program

Code:

A            14.0000

RCL 1         1.5000

RCL 2        -4.5000

P<>S

RCL 0         2.0000

RCL 1       -12.0000

RCL 2        42.0000

RCL 3       -52.0000

P<>S

Code:

B             1.5000

x<>y         -3.0000

Conclusion

\(2x^5-9x^4+15x^3+65x^2-267x+234=\)
\((x^2+1.5x-4.5)(2x^3-12x^2+42x-52)\)

Solutions

For \(x^2+1.5x-4.5=0\):
\(x_1=1.5\)
\(x_2=-3\)

Initialize guess

Code:

1   STO 1

    STO 2

Run program again

Code:

A             12.0000

RCL 1         -4.0000

RCL 2         13.0000

P<>S

RCL 0          2.0000

RCL 1         -4.0000

P<>S

Code:

B               Error

CLx           -9.0000

CHS            9.0000

√x             3.0000

x<>y           2.0000

Code:

P<>S

RCL 1         -4.0000

RCL 0          2.0000

÷             -2.0000

CHS            2.0000

P<>S

Conclusion

\(2x^3-12x^2+42x-52=\)
\((x^2-4x+13)(2x-4)\)

Solutions

For \(x^2-4x+13=0\):
\(x_3=2+3i\)
\(x_4=2-3i\)

For \(2x-4=0\):
\(x_5=2\)

Summary

Factors

\(2x^5-9x^4+15x^3+65x^2-267x+234=\)
\((x^2+1.5x-4.5)(x^2-4x+13)(2x-4)=\)
\((x-1.5)(x+3)(x^2-4x+13)2(x-2)=\)
\((2x-3)(x+3)(x^2-4x+13)(x-2)\)

Solutions

\(x_1=1.5\)
\(x_2=-3\)
\(x_3=2+3i\)
\(x_4=2-3i\)
\(x_5=2\)

plore90 · 08-14-2024, 03:28 PM

Thanks so much Thomas!!!!

Thomas Klemm · 08-14-2024, 05:29 PM

Let me add a few notes:

The program is based on the similar program for the HP-11C.
As I'm not that familiar with the HP-67, there may be room for improvements.
With \(10\) secondary registers, polynomials up to degree \(n = 9\) can be solved.
However, this can easily be extended to \(n = 14\) by using registers A-E.
As registers 8 and 9 are not used, we could start with register 8 instead of register 10.
This means the maximum degree is \(n = 16\).
For this to work, some minor code changes are required.
However, entering the coefficients becomes cumbersome, so I don't think it's generally worth it.
The listing can be used with this online HP-67 emulator.
The program is slow, so you have plenty of time watching the blinkenlicht.

Here is the data for the emulator from the example above:

plore90 · 08-14-2024, 09:35 PM

Thank's Thomas
Paolo